From 92acf99a6124df0d2e10bf10f296962ab9383ba1 Mon Sep 17 00:00:00 2001
From: Tom Hochstein <tom.hochstein@nxp.com>
Date: Thu, 13 Jan 2022 17:56:08 -0600
Subject: imx-boot,u-boot-imx: Add bootloader image size to SD card image

Append a tag to the bootloader image used in the SD card image. The tag
contains the size of the bootloader image so UUU can easily find the end of
the bootloader in the SD card image.

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>
---
 classes/uuu_bootloader_tag.bbclass               | 11 +++++++++++
 recipes-bsp/imx-mkimage/imx-boot_1.0.bb          | 10 ++++++----
 recipes-bsp/u-boot/u-boot-imx-mfgtool_2021.04.bb |  4 ++++
 recipes-bsp/u-boot/u-boot-imx_2021.04.bb         |  9 +++++++++
 4 files changed, 30 insertions(+), 4 deletions(-)
 create mode 100644 classes/uuu_bootloader_tag.bbclass

diff --git a/classes/uuu_bootloader_tag.bbclass b/classes/uuu_bootloader_tag.bbclass
new file mode 100644
index 00000000..fb6acd72
--- /dev/null
+++ b/classes/uuu_bootloader_tag.bbclass
@@ -0,0 +1,11 @@
+# Append a tag to the bootloader image used in the SD card image. The tag
+# contains the size of the bootloader image so UUU can easily find the end of
+# the bootloader in the SD card image.
+do_deploy:append() {
+    if [ "${UUU_BOOTLOADER}" != "" ]; then
+        cp ${DEPLOYDIR}/${UUU_BOOTLOADER}   ${DEPLOYDIR}/${UUU_BOOTLOADER_TAGGED}
+        ln -sf ${UUU_BOOTLOADER_TAGGED}     ${DEPLOYDIR}/${UUU_BOOTLOADER}
+        stat -L -cUUUBURNXXOEUZX7+A-XY5601QQWWZ%sEND ${DEPLOYDIR}/${UUU_BOOTLOADER} \
+                                         >> ${DEPLOYDIR}/${UUU_BOOTLOADER}
+    fi
+}
diff --git a/recipes-bsp/imx-mkimage/imx-boot_1.0.bb b/recipes-bsp/imx-mkimage/imx-boot_1.0.bb
index f8ebb730..b332e079 100644
--- a/recipes-bsp/imx-mkimage/imx-boot_1.0.bb
+++ b/recipes-bsp/imx-mkimage/imx-boot_1.0.bb
@@ -24,7 +24,10 @@ DEPENDS:append:mx8m = " u-boot-mkimage-native dtc-native"
 BOOT_NAME = "imx-boot"
 PROVIDES = "${BOOT_NAME}"
 
-inherit deploy
+inherit deploy uuu_bootloader_tag
+
+UUU_BOOTLOADER        = "${BOOT_NAME}"
+UUU_BOOTLOADER_TAGGED = "${BOOT_NAME}-tagged"
 
 # Add CFLAGS with native INCDIR & LIBDIR for imx-mkimage build
 CFLAGS = "-O2 -Wall -std=c99 -I ${STAGING_INCDIR_NATIVE} -L ${STAGING_LIBDIR_NATIVE}"
@@ -190,9 +193,8 @@ do_deploy() {
         fi
         install -m 0644 ${S}/${BOOT_CONFIG_MACHINE}-${target} ${DEPLOYDIR}
     done
-    cd ${DEPLOYDIR}
-    ln -sf ${BOOT_CONFIG_MACHINE}-${IMAGE_IMXBOOT_TARGET} ${BOOT_NAME}
-    cd -
+
+    ln -sf ${BOOT_CONFIG_MACHINE}-${IMAGE_IMXBOOT_TARGET}    ${DEPLOYDIR}/${BOOT_NAME}
 }
 addtask deploy before do_build after do_compile
 
diff --git a/recipes-bsp/u-boot/u-boot-imx-mfgtool_2021.04.bb b/recipes-bsp/u-boot/u-boot-imx-mfgtool_2021.04.bb
index af502889..5443ceac 100644
--- a/recipes-bsp/u-boot/u-boot-imx-mfgtool_2021.04.bb
+++ b/recipes-bsp/u-boot/u-boot-imx-mfgtool_2021.04.bb
@@ -6,3 +6,7 @@ FILESEXTRAPATHS:prepend := "${THISDIR}/u-boot-imx:"
 
 require u-boot-imx_${PV}.bb
 require u-boot-mfgtool.inc
+
+UUU_BOOTLOADER_TAGGED     = ""
+UUU_BOOTLOADER_TAGGED:mx6 = "u-boot-mfgtool-tagged.${UBOOT_SUFFIX}"
+UUU_BOOTLOADER_TAGGED:mx7 = "u-boot-mfgtool-tagged.${UBOOT_SUFFIX}"
diff --git a/recipes-bsp/u-boot/u-boot-imx_2021.04.bb b/recipes-bsp/u-boot/u-boot-imx_2021.04.bb
index bb5809e2..96552eef 100644
--- a/recipes-bsp/u-boot/u-boot-imx_2021.04.bb
+++ b/recipes-bsp/u-boot/u-boot-imx_2021.04.bb
@@ -7,6 +7,15 @@ require u-boot-imx-common_${PV}.inc
 
 PROVIDES += "u-boot"
 
+inherit uuu_bootloader_tag
+
+UUU_BOOTLOADER            = ""
+UUU_BOOTLOADER:mx6        = "${UBOOT_BINARY}"
+UUU_BOOTLOADER:mx7        = "${UBOOT_BINARY}"
+UUU_BOOTLOADER_TAGGED     = ""
+UUU_BOOTLOADER_TAGGED:mx6 = "u-boot-tagged.${UBOOT_SUFFIX}"
+UUU_BOOTLOADER_TAGGED:mx7 = "u-boot-tagged.${UBOOT_SUFFIX}"
+
 do_deploy:append:mx8m() {
     # Deploy u-boot-nodtb.bin and fsl-imx8m*-XX.dtb for mkimage to generate boot binary
     if [ -n "${UBOOT_CONFIG}" ]
-- 
cgit v1.2.3-54-g00ecf