diff options
Diffstat (limited to 'recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.0.imx.bb')
-rw-r--r-- | recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.0.imx.bb | 147 |
1 files changed, 147 insertions, 0 deletions
diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.0.imx.bb b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.0.imx.bb new file mode 100644 index 00000000..04cb5a5b --- /dev/null +++ b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.0.imx.bb | |||
@@ -0,0 +1,147 @@ | |||
1 | # This recipe is for the i.MX fork of gstreamer1.0-plugins-base. For ease of | ||
2 | # maintenance, the top section is a verbatim copy of an OE-core | ||
3 | # recipe. The second section customizes the recipe for i.MX. | ||
4 | |||
5 | ########### OE-core copy ################## | ||
6 | # Upstream hash: fb2d28e0315ece6180c87c7047587673024a09f7 | ||
7 | |||
8 | require gstreamer1.0-plugins-common.inc | ||
9 | |||
10 | DESCRIPTION = "'Base' GStreamer plugins and helper libraries" | ||
11 | HOMEPAGE = "https://gstreamer.freedesktop.org/" | ||
12 | BUGTRACKER = "https://gitlab.freedesktop.org/gstreamer/gst-plugins-base/-/issues" | ||
13 | LICENSE = "LGPL-2.1-or-later" | ||
14 | LIC_FILES_CHKSUM = "file://COPYING;md5=69333daa044cb77e486cc36129f7a770" | ||
15 | |||
16 | SRC_URI = "https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \ | ||
17 | file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \ | ||
18 | file://0003-viv-fb-Make-sure-config.h-is-included.patch \ | ||
19 | file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch \ | ||
20 | " | ||
21 | SRC_URI[sha256sum] = "f53672294f3985d56355c8b1df8f6b49c8c8721106563e19f53be3507ff2229d" | ||
22 | |||
23 | S = "${WORKDIR}/gst-plugins-base-${PV}" | ||
24 | |||
25 | DEPENDS += "iso-codes util-linux zlib" | ||
26 | |||
27 | inherit gobject-introspection | ||
28 | |||
29 | # opengl packageconfig factored out to make it easy for distros | ||
30 | # and BSP layers to choose OpenGL APIs/platforms/window systems | ||
31 | PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl', '', d)}" | ||
32 | |||
33 | PACKAGECONFIG ??= " \ | ||
34 | ${GSTREAMER_ORC} \ | ||
35 | ${PACKAGECONFIG_GL} \ | ||
36 | ${@bb.utils.filter('DISTRO_FEATURES', 'alsa x11', d)} \ | ||
37 | jpeg ogg pango png theora vorbis \ | ||
38 | ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland egl', '', d)} \ | ||
39 | " | ||
40 | |||
41 | OPENGL_APIS = 'opengl gles2' | ||
42 | OPENGL_PLATFORMS = 'egl' | ||
43 | |||
44 | X11DEPENDS = "virtual/libx11 libsm libxrender libxv" | ||
45 | X11ENABLEOPTS = "-Dx11=enabled -Dxvideo=enabled -Dxshm=enabled" | ||
46 | X11DISABLEOPTS = "-Dx11=disabled -Dxvideo=disabled -Dxshm=disabled" | ||
47 | |||
48 | PACKAGECONFIG[alsa] = "-Dalsa=enabled,-Dalsa=disabled,alsa-lib" | ||
49 | PACKAGECONFIG[cdparanoia] = "-Dcdparanoia=enabled,-Dcdparanoia=disabled,cdparanoia" | ||
50 | PACKAGECONFIG[graphene] = "-Dgl-graphene=enabled,-Dgl-graphene=disabled,graphene" | ||
51 | PACKAGECONFIG[jpeg] = "-Dgl-jpeg=enabled,-Dgl-jpeg=disabled,jpeg" | ||
52 | PACKAGECONFIG[ogg] = "-Dogg=enabled,-Dogg=disabled,libogg" | ||
53 | PACKAGECONFIG[opus] = "-Dopus=enabled,-Dopus=disabled,libopus" | ||
54 | PACKAGECONFIG[pango] = "-Dpango=enabled,-Dpango=disabled,pango" | ||
55 | PACKAGECONFIG[png] = "-Dgl-png=enabled,-Dgl-png=disabled,libpng" | ||
56 | # This enables Qt5 QML examples in -base. The Qt5 GStreamer | ||
57 | # qmlglsink and qmlglsrc plugins still exist in -good. | ||
58 | PACKAGECONFIG[qt5] = "-Dqt5=enabled,-Dqt5=disabled,qtbase qtdeclarative qtbase-native" | ||
59 | PACKAGECONFIG[theora] = "-Dtheora=enabled,-Dtheora=disabled,libtheora" | ||
60 | PACKAGECONFIG[tremor] = "-Dtremor=enabled,-Dtremor=disabled,tremor" | ||
61 | PACKAGECONFIG[visual] = "-Dlibvisual=enabled,-Dlibvisual=disabled,libvisual" | ||
62 | PACKAGECONFIG[vorbis] = "-Dvorbis=enabled,-Dvorbis=disabled,libvorbis" | ||
63 | PACKAGECONFIG[x11] = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}" | ||
64 | |||
65 | # OpenGL API packageconfigs | ||
66 | PACKAGECONFIG[opengl] = ",,virtual/libgl libglu" | ||
67 | PACKAGECONFIG[gles2] = ",,virtual/libgles2" | ||
68 | |||
69 | # OpenGL platform packageconfigs | ||
70 | PACKAGECONFIG[egl] = ",,virtual/egl" | ||
71 | |||
72 | # OpenGL window systems (except for X11) | ||
73 | PACKAGECONFIG[gbm] = ",,virtual/libgbm libgudev libdrm" | ||
74 | PACKAGECONFIG[wayland] = ",,wayland-native wayland wayland-protocols libdrm" | ||
75 | PACKAGECONFIG[dispmanx] = ",,virtual/libomxil" | ||
76 | PACKAGECONFIG[viv-fb] = ",,virtual/libgles2 virtual/libg2d" | ||
77 | |||
78 | OPENGL_WINSYS = "${@bb.utils.filter('PACKAGECONFIG', 'x11 gbm wayland dispmanx egl viv-fb', d)}" | ||
79 | |||
80 | EXTRA_OEMESON += " \ | ||
81 | -Ddoc=disabled \ | ||
82 | ${@get_opengl_cmdline_list('gl_api', d.getVar('OPENGL_APIS'), d)} \ | ||
83 | ${@get_opengl_cmdline_list('gl_platform', d.getVar('OPENGL_PLATFORMS'), d)} \ | ||
84 | ${@get_opengl_cmdline_list('gl_winsys', d.getVar('OPENGL_WINSYS'), d)} \ | ||
85 | " | ||
86 | |||
87 | FILES:${PN}-dev += "${libdir}/gstreamer-1.0/include/gst/gl/gstglconfig.h" | ||
88 | FILES:${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict" | ||
89 | |||
90 | def get_opengl_cmdline_list(switch_name, options, d): | ||
91 | selected_options = [] | ||
92 | if bb.utils.contains('DISTRO_FEATURES', 'opengl', True, False, d): | ||
93 | for option in options.split(): | ||
94 | if bb.utils.contains('PACKAGECONFIG', option, True, False, d): | ||
95 | selected_options += [option] | ||
96 | if selected_options: | ||
97 | return '-D' + switch_name + '=' + ','.join(selected_options) | ||
98 | else: | ||
99 | return '' | ||
100 | |||
101 | CVE_PRODUCT += "gst-plugins-base" | ||
102 | |||
103 | ########### End of OE-core copy ########### | ||
104 | |||
105 | ########### i.MX overrides ################ | ||
106 | |||
107 | DEFAULT_PREFERENCE = "-1" | ||
108 | |||
109 | LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=69333daa044cb77e486cc36129f7a770" | ||
110 | |||
111 | SRC_URI:remove = " \ | ||
112 | https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \ | ||
113 | file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \ | ||
114 | file://0003-viv-fb-Make-sure-config.h-is-included.patch \ | ||
115 | file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch" | ||
116 | SRC_URI:prepend = "${GST1.0-PLUGINS-BASE_SRC};branch=${SRCBRANCH} " | ||
117 | GST1.0-PLUGINS-BASE_SRC ?= "gitsm://github.com/nxp-imx/gst-plugins-base.git;protocol=https" | ||
118 | SRCBRANCH = "MM_04.08.00_2305_L6.1.y" | ||
119 | SRCREV = "aaaf7df211523b1835659ae85c510e5615d451d7" | ||
120 | |||
121 | S = "${WORKDIR}/git" | ||
122 | |||
123 | inherit use-imx-headers | ||
124 | |||
125 | PACKAGECONFIG_GL:imxgpu2d = \ | ||
126 | "${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl viv-fb', '', d)}" | ||
127 | PACKAGECONFIG_GL:imxgpu3d = \ | ||
128 | "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl viv-fb', '', d)}" | ||
129 | PACKAGECONFIG_GL:use-mainline-bsp = \ | ||
130 | "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl gbm', '', d)}" | ||
131 | |||
132 | PACKAGECONFIG_REMOVE ?= "jpeg" | ||
133 | PACKAGECONFIG:remove = "${PACKAGECONFIG_REMOVE}" | ||
134 | PACKAGECONFIG:append:imxgpu2d = " g2d" | ||
135 | |||
136 | PACKAGECONFIG[g2d] = ",,virtual/libg2d" | ||
137 | PACKAGECONFIG[viv-fb] = ",,virtual/libgles2" | ||
138 | |||
139 | EXTRA_OEMESON += "-Dc_args="${CFLAGS} -I${STAGING_INCDIR_IMX}"" | ||
140 | |||
141 | # links with imx-gpu libs which are pre-built for glibc | ||
142 | # gcompat will address it during runtime | ||
143 | LDFLAGS:append:imxgpu:libc-musl = " -Wl,--allow-shlib-undefined" | ||
144 | |||
145 | COMPATIBLE_MACHINE = "(imx-nxp-bsp)" | ||
146 | |||
147 | ########### End of i.MX overrides ######### | ||