diff options
Diffstat (limited to 'recipes-bsp/libimxdmabuffer/libimxdmabuffer_1.1.2.bb')
-rw-r--r-- | recipes-bsp/libimxdmabuffer/libimxdmabuffer_1.1.2.bb | 55 |
1 files changed, 55 insertions, 0 deletions
diff --git a/recipes-bsp/libimxdmabuffer/libimxdmabuffer_1.1.2.bb b/recipes-bsp/libimxdmabuffer/libimxdmabuffer_1.1.2.bb new file mode 100644 index 00000000..dd3b65da --- /dev/null +++ b/recipes-bsp/libimxdmabuffer/libimxdmabuffer_1.1.2.bb | |||
@@ -0,0 +1,55 @@ | |||
1 | DESCRIPTION = 'Library for allocating and managing physically contiguous memory \ | ||
2 | ("DMA memory" or "DMA buffers") on i.MX devices.' | ||
3 | HOMEPAGE = "https://github.com/Freescale/libimxdmabuffer" | ||
4 | LICENSE = "LGPLv2.1" | ||
5 | LIC_FILES_CHKSUM = "file://LICENSE;md5=38fa42a5a6425b26d2919b17b1527324" | ||
6 | SECTION = "base" | ||
7 | |||
8 | PV .= "+git${SRCPV}" | ||
9 | |||
10 | SRCBRANCH ?= "master" | ||
11 | SRCREV = "5410b44fb0c5bbd9fb1f3ba0681e65068d8cde57" | ||
12 | SRC_URI = "git://github.com/Freescale/libimxdmabuffer.git;branch=${SRCBRANCH};protocol=https \ | ||
13 | file://0001-g2d-Fix-typo.patch \ | ||
14 | file://run-ptest \ | ||
15 | " | ||
16 | |||
17 | |||
18 | S = "${WORKDIR}/git" | ||
19 | |||
20 | inherit pkgconfig waf use-imx-headers ptest | ||
21 | |||
22 | # dma-heap allocator is unavailable because it requires kernel 5.6 or newer. | ||
23 | EXTRA_OECONF = "--imx-linux-headers-path=${STAGING_INCDIR_IMX} \ | ||
24 | --libdir=${libdir} \ | ||
25 | --with-dma-heap-allocator=no \ | ||
26 | ${PACKAGECONFIG_CONFARGS}" | ||
27 | |||
28 | # If imxdpu is in use, the DPU is also used for implementing | ||
29 | # libg2d. However, that implementation's g2d_alloc() function | ||
30 | # is broken, so we cannot use it. | ||
31 | LIBG2D_PACKAGECONFIG = "g2d" | ||
32 | LIBG2D_PACKAGECONFIG_imxdpu = "" | ||
33 | |||
34 | PACKAGECONFIG ?= " ion " | ||
35 | PACKAGECONFIG_append_imxgpu2d = " ${LIBG2D_PACKAGECONFIG}" | ||
36 | PACKAGECONFIG_append_imxipu = " ipu" | ||
37 | PACKAGECONFIG_append_imxpxp = " pxp" | ||
38 | PACKAGECONFIG_append_mx8m = " dwl" | ||
39 | |||
40 | HANTRO_CONF = "--hantro-headers-path=${STAGING_INCDIR}/hantro_dec --hantro-decoder-version=G2" | ||
41 | |||
42 | PACKAGECONFIG[dwl] = "--with-dwl-allocator=yes ${HANTRO_CONF},--with-dwl-allocator=no,imx-vpu-hantro" | ||
43 | PACKAGECONFIG[ion] = "--with-ion-allocator=yes, --with-ion-allocator=no," | ||
44 | PACKAGECONFIG[ipu] = "--with-ipu-allocator=yes, --with-ipu-allocator=no," | ||
45 | PACKAGECONFIG[g2d] = "--with-g2d-allocator=yes, --with-g2d-allocator=no,virtual/libg2d" | ||
46 | PACKAGECONFIG[pxp] = "--with-pxp-allocator=yes, --with-pxp-allocator=no," | ||
47 | |||
48 | # Using do_install_ptest_base instead of do_install_ptest, since | ||
49 | # the default do_install_ptest_base is hardcoded to expect Makefiles. | ||
50 | do_install_ptest_base() { | ||
51 | install -D ${WORKDIR}/run-ptest ${D}${PTEST_PATH}/run-ptest | ||
52 | install -m 0755 ${B}/test-alloc ${D}${PTEST_PATH} | ||
53 | } | ||
54 | |||
55 | COMPATIBLE_MACHINE = "(mx6|mx7|mx8)" | ||