1 files changed, 51 insertions, 0 deletions

diff --git a/recipes-bsp/imx-atf/imx-atf_2.4.bb b/recipes-bsp/imx-atf/imx-atf_2.4.bb
new file mode 100644
index 00000000..07807eff
--- /dev/null
+++ b/recipes-bsp/imx-atf/imx-atf_2.4.bb
@@ -0,0 +1,51 @@
+# Copyright (C) 2017-2021 NXP
+
+DESCRIPTION = "i.MX ARM Trusted Firmware"
+SECTION = "BSP"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
+
+PV .= "+git${SRCPV}"
+
+SRCBRANCH = "imx_5.4.70_2.3.0"
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-atf.git;protocol=https;branch=${SRCBRANCH} \
+"
+SRCREV = "2a26786460edd4f0ec3111e7027c93c57fc572c1"
+
+S = "${WORKDIR}/git"
+
+inherit deploy
+
+BOOT_TOOLS = "imx-boot-tools"
+
+ATF_PLATFORM ??= "INVALID"
+
+EXTRA_OEMAKE += " \
+    CROSS_COMPILE="${TARGET_PREFIX}" \
+    PLAT=${ATF_PLATFORM} \
+"
+
+BUILD_OPTEE = "${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'true', 'false', d)}"
+
+do_compile() {
+    # Clear LDFLAGS to avoid the option -Wl recognize issue
+    unset LDFLAGS
+    oe_runmake bl31
+    if ${BUILD_OPTEE}; then
+       oe_runmake clean BUILD_BASE=build-optee
+       oe_runmake BUILD_BASE=build-optee SPD=opteed bl31
+    fi
+}
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    install -Dm 0644 ${S}/build/${ATF_PLATFORM}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${ATF_PLATFORM}.bin
+    if ${BUILD_OPTEE}; then
+       install -m 0644 ${S}/build-optee/${ATF_PLATFORM}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${ATF_PLATFORM}.bin-optee
+    fi
+}
+addtask deploy after do_compile
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(mx8|imx-boot-container)"