1 files changed, 92 insertions, 0 deletions

diff --git a/recipes-bsp/firmware-imx/firmware-imx_7.5.bb b/recipes-bsp/firmware-imx/firmware-imx_7.5.bb
new file mode 100644
index 00000000..3bebe5b2
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx_7.5.bb
@@ -0,0 +1,92 @@
+# Copyright (C) 2012-2016 Freescale Semiconductor
+# Copyright (C) 2018 O.S. Systems Software LTDA.
+SUMMARY = "Freescale IMX firmware"
+DESCRIPTION = "Freescale IMX firmware such as for the VPU"
+SECTION = "base"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=75abe2fa1d16ca79f87cde926f05f72d"
+
+PE = "1"
+
+SRCBRANCH ?= "master"
+SRC_URI = "${FSL_MIRROR}/firmware-imx-${PV}.bin;fsl-eula=true \
+           git://github.com/NXP/imx-firmware.git;protocol=https;branch=${SRCBRANCH};destsuffix=${S}/git"
+
+#BRCM firmware git
+SRCREV = "8ce9046f5058fdd2c5271f86ccfc61bc5a248ae3"
+
+SRC_URI[md5sum] = "3851bb89ff262e9322a631755215f538"
+SRC_URI[sha256sum] = "a8f099bdf786b2da1e8b43094950c033ccdbf93f1b8a93caffb912e1500cd735"
+
+inherit fsl-eula-unpack allarch
+
+do_install() {
+    install -d ${D}${base_libdir}/firmware/imx
+    install -d ${D}${base_libdir}/firmware/bcm
+    install -d ${D}${sysconfdir}/firmware
+
+    cp -rfv firmware/* ${D}${base_libdir}/firmware/
+
+    # FIXME: This need to be removed when iMX8 is integrated.
+    rm -rf ${D}${base_libdir}/firmware/ddr \
+           ${D}${base_libdir}/firmware/hdmi \
+           ${D}${base_libdir}/firmware/seco
+
+    #1BW_BCM43340
+    install -d ${D}${base_libdir}/firmware/bcm/1BW_BCM43340
+    cp -rfv git/brcm/1BW_BCM43340/*.bin ${D}${base_libdir}/firmware/bcm/1BW_BCM43340
+    cp -rfv git/brcm/1BW_BCM43340/*.cal ${D}${base_libdir}/firmware/bcm/1BW_BCM43340
+    cp -rfv git/brcm/1BW_BCM43340/*.hcd ${D}${sysconfdir}/firmware/
+
+    #1DX_BCM4343W
+    install -d ${D}${base_libdir}/firmware/bcm/1DX_BCM4343W
+    cp -rfv git/brcm/1DX_BCM4343W/*.bin ${D}${base_libdir}/firmware/bcm/1DX_BCM4343W
+    cp -rfv git/brcm/1DX_BCM4343W/*.cal ${D}${base_libdir}/firmware/bcm/1DX_BCM4343W
+    cp -rfv git/brcm/1DX_BCM4343W/*.hcd ${D}${sysconfdir}/firmware/
+
+    #SN8000_BCM43362
+    install -d ${D}${base_libdir}/firmware/bcm/SN8000_BCM43362
+    cp -rfv git/brcm/SN8000_BCM43362/*.bin ${D}${base_libdir}/firmware/bcm/SN8000_BCM43362
+    cp -rfv git/brcm/SN8000_BCM43362/*.cal ${D}${base_libdir}/firmware/bcm/SN8000_BCM43362
+    cp -rfv git/brcm/1DX_BCM4343W/*.hcd ${D}${sysconfdir}/firmware/
+
+    #ZP_BCM4339
+    install -d ${D}${base_libdir}/firmware/bcm/ZP_BCM4339
+    cp -rfv git/brcm/ZP_BCM4339/*.bin ${D}${base_libdir}/firmware/bcm/ZP_BCM4339
+    cp -rfv git/brcm/ZP_BCM4339/*.cal ${D}${base_libdir}/firmware/bcm/ZP_BCM4339
+    cp -rfv git/brcm/ZP_BCM4339/*.hcd ${D}${sysconfdir}/firmware/
+
+    mv ${D}${base_libdir}/firmware/epdc/ ${D}${base_libdir}/firmware/imx/epdc/
+    mv ${D}${base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw.nonrestricted ${D}${base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw
+
+    find ${D}${base_libdir}/firmware -type f -exec chmod 644 '{}' ';'
+    find ${D}${base_libdir}/firmware -type f -exec chown root:root '{}' ';'
+
+    # Remove files not going to be installed
+    find ${D}${base_libdir}/firmware/ -name '*.mk' -exec rm '{}' ';'
+}
+
+python populate_packages_prepend() {
+    vpudir = bb.data.expand('${base_libdir}/firmware/vpu', d)
+    do_split_packages(d, vpudir, '^vpu_fw_([^_]*).*\.bin',
+                      output_pattern='firmware-imx-vpu-%s',
+                      description='Freescale IMX Firmware %s',
+                      extra_depends='',
+                      prepend=True)
+
+    sdmadir = bb.data.expand('${base_libdir}/firmware/sdma', d)
+    do_split_packages(d, sdmadir, '^sdma-([^-]*).*\.bin',
+                      output_pattern='firmware-imx-sdma-%s',
+                      description='Freescale IMX Firmware %s',
+                      extra_depends='',
+                      prepend=True)
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGES_DYNAMIC = "${PN}-vpu-* ${PN}-sdma-*"
+
+PACKAGES =+ "${PN}-epdc ${PN}-brcm"
+
+FILES_${PN}-epdc = "${base_libdir}/firmware/imx/epdc/"
+FILES_${PN}-brcm = "${base_libdir}/firmware/bcm/*/*.bin ${base_libdir}/firmware/bcm/*/*.cal ${sysconfdir}/firmware/"