Move meta-fsl-ppc content to layer root

This commit is just a rename of all contents of meta-fsl-ppc
subdirectory to this layer's root, merging the contents of common
files, subsequent changes are based on top of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

4 files changed, 175 insertions, 0 deletions

diff --git a/recipes-virtualization/hv-cfg/hv-cfg_git.bb b/recipes-virtualization/hv-cfg/hv-cfg_git.bb
new file mode 100644
index 00000000..e4f18e07
--- /dev/null
+++ b/recipes-virtualization/hv-cfg/hv-cfg_git.bb
@@ -0,0 +1,52 @@
+DESCRIPTION = "Hypervisor Config"
+SECTION = "hv-cfg"
+LICENSE = "BSD"
+PR = "r6"
+
+LIC_FILES_CHKSUM = " \
+        file://p2041rdb/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+        file://p3041ds/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+        file://p4080ds/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+        file://p5020ds/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+"
+
+DEPENDS += "dtc-native"
+
+# this package is specific to the machine itself
+INHIBIT_DEFAULT_DEPS = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/hv-cfg.git;nobranch=1"
+SRCREV = "b9287b07390d17bfba936a806a72b91b89507c22"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+        make install
+
+        M=`echo ${MACHINE} | sed s/-64b//g`
+        if [ "t1042d4rdb" = "${M}" ] || [ "t1040d4rdb" = "${M}" ];then
+                M=t1040rdb
+        fi
+        install -d ${D}/boot/hv-cfg
+        cp -r ${S}/${M}/${M}/* ${D}/boot/hv-cfg
+}
+
+do_deploy () {
+        M=`echo ${MACHINE} | sed s/-64b//g`
+        if [ "t1042d4rdb" = "${M}" ] || [ "t1040d4rdb" = "${M}" ];then
+                M=t1040rdb
+        fi
+        install -d ${DEPLOYDIR}/hv-cfg
+        cp -r ${S}/${M}/${M}/* ${DEPLOYDIR}/hv-cfg
+}
+addtask deploy after do_install
+
+PACKAGES += "${PN}-image"
+FILES_${PN}-image += "/boot"
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
+ALLOW_EMPTY_${PN} = "1"
diff --git a/recipes-virtualization/hypervisor/files/81-fsl-embedded-hv.rules b/recipes-virtualization/hypervisor/files/81-fsl-embedded-hv.rules
new file mode 100644
index 00000000..5edfa113
--- /dev/null
+++ b/recipes-virtualization/hypervisor/files/81-fsl-embedded-hv.rules
@@ -0,0 +1,2 @@
+# Add rule to handle setting up device node for FSL HV mgmt driver
+SUBSYSTEM=="misc", KERNEL=="fsl-hv", NAME="fsl-hv"
diff --git a/recipes-virtualization/hypervisor/hypervisor_git.bb b/recipes-virtualization/hypervisor/hypervisor_git.bb
new file mode 100644
index 00000000..80ba635f
--- /dev/null
+++ b/recipes-virtualization/hypervisor/hypervisor_git.bb
@@ -0,0 +1,94 @@
+DESCRIPTION = "Freescale embedded hypervisor"
+SECTION = "embedded-hv"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://README;endline=22;md5=0655bbc3b7d7166c30c87208b4e23cf0"
+
+PR = "r3"
+
+DEPENDS = "u-boot-mkimage-native"
+
+inherit deploy
+
+# TODO: fix dtc to use the already built package
+SRC_URI = " \
+        git://git.freescale.com/ppc/sdk/hypervisor/hypervisor.git;name=hypervisor;nobranch=1 \
+        git://git.freescale.com/ppc/sdk/hypervisor/kconfig.git;name=kconfig;destsuffix=git/kconfig;nobranch=1 \
+        git://git.freescale.com/ppc/sdk/hypervisor/libos.git;name=libos;destsuffix=git/libos;nobranch=1 \
+        git://git.kernel.org/pub/scm/utils/dtc/dtc.git;name=dtc;destsuffix=dtc \
+        git://git.freescale.com/ppc/sdk/hypertrk.git;name=hypertrk;destsuffix=git/hypertrk;nobranch=1 \
+        file://81-fsl-embedded-hv.rules \
+          "
+
+SRCREV_FORMAT="hypervisor"
+SRCREV = "e17b3ecbbdadebf7e31ba21134b689334da74e10"
+SRCREV_kconfig = "a56025d4da992b856796b0eccac2e410d751dbac"
+SRCREV_libos = "2ff7649c8047dd0d2143acb4743c53e6e6ba4878"
+SRCREV_dtc = "a6d55e039fd22048687fe061b4609e2807efe764"
+SRCREV_hypertrk = "975c98b562186afbd3bbf103ae54b96cf9b3e533"
+
+S = "${WORKDIR}/git"
+
+OUTPUT ?= "output32"
+OUTPUT_powerpc64 = "output64"
+
+EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}" O="${OUTPUT}"'
+
+DEFCONFIG = "defconfig"
+DEFCONFIG_powerpc64 = "64bit_defconfig"
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
+
+inherit cml1
+do_configure () {
+        oe_runmake ${DEFCONFIG}
+}
+
+PKG_HV_HYPERTRK_SUPPORT = "n"
+do_compile () {
+        if [ "${PKG_HV_HYPERTRK_SUPPORT}" = "y" ]
+        then
+                oe_runmake silentoldconfig
+                export HV_DIR=$PWD
+                cd hypertrk
+                oe_runmake deploy
+                cd ..
+        fi
+
+        oe_runmake
+        oe_runmake partman
+}
+
+do_install () {
+        install -d ${D}/${bindir}
+        install ${B}/${OUTPUT}/bin/linux/partman ${D}/${bindir}/partman
+
+        install -d ${D}${sysconfdir}/udev/rules.d
+        install -m 0644 ${WORKDIR}/81-fsl-embedded-hv.rules ${D}${sysconfdir}/udev/rules.d
+
+        install -d ${D}/boot/hv
+        install ${B}/${OUTPUT}/.config ${D}/boot/hv/hypervisor.config
+        install -m 644 ${B}/${OUTPUT}/bin/hv ${B}/${OUTPUT}/bin/hv.map \
+                ${B}/${OUTPUT}/bin/hv.uImage ${B}/${OUTPUT}/bin/hv.bin \
+                        ${D}/boot/hv/
+}
+
+do_deploy () {
+        install -d ${DEPLOYDIR}/hv/
+        install ${B}/${OUTPUT}/.config ${DEPLOYDIR}/hv/hypervisor.config
+        install -m 644 ${B}/${OUTPUT}/bin/hv ${B}/${OUTPUT}/bin/hv.map \
+                ${B}/${OUTPUT}/bin/hv.uImage ${B}/${OUTPUT}/bin/hv.bin \
+                        ${DEPLOYDIR}/hv/
+}
+addtask deploy before do_build after do_install
+
+do_deploy_append() {
+        rm -f ${B}/../hv
+}
+
+INSANE_SKIP_${PN} = 'already-stripped'
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+ALLOW_EMPTY_${PN} = "1"
+PACKAGES_prepend = "${PN}-image ${PN}-partman "
+FILES_${PN}-image = "/boot/"
+FILES_${PN}-partman = "${bindir}/partman"
diff --git a/recipes-virtualization/mux-server/mux-server_1.02.bb b/recipes-virtualization/mux-server/mux-server_1.02.bb
new file mode 100644
index 00000000..744a84c2
--- /dev/null
+++ b/recipes-virtualization/mux-server/mux-server_1.02.bb
@@ -0,0 +1,27 @@
+DESCRIPTION = "A Linux-based utility supporting console multiplexing and demultiplexing"
+SECTION = "mux-server"
+LICENSE = "LGPL-2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/hypervisor/mux_server.git;branch=master"
+SRCREV = "3e4c6a44a81bb5cf2996830e8034d26850f80efc"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE='HOSTCC="${CC}"'
+
+inherit deploy
+
+do_install () {
+    install -d ${D}${bindir}
+    install -m 755 mux_server ${D}${bindir}
+}
+
+do_deploy() {
+    install -d ${DEPLOYDIR}/hv
+    install -m 755 mux_server ${DEPLOYDIR}/hv/mux_server-${PKGV}-${PKGR}
+    ln -sf mux_server-${PKGV}-${PKGR} ${DEPLOYDIR}/hv/mux_server
+}
+addtask deploy after do_install
+
+BBCLASSEXTEND = "native nativesdk"