optee-test-qoriq: upgrade to 3.8.0

Switch to use codes from https://github.com/OP-TEE/optee_test,
tag: 3.8.0

Signed-off-by: Ting Liu <ting.liu@nxp.com>

1 files changed, 47 insertions, 0 deletions

diff --git a/recipes-security/optee/optee-test-qoriq_3.8.0.bb b/recipes-security/optee/optee-test-qoriq_3.8.0.bb
new file mode 100644
index 00000000..f46f8c6f
--- /dev/null
+++ b/recipes-security/optee/optee-test-qoriq_3.8.0.bb
@@ -0,0 +1,47 @@
+SUMMARY = "OP-TEE sanity testsuite"
+HOMEPAGE = "https://github.com/OP-TEE/optee_test"
+
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE.md;md5=daa2bcccc666345ab8940aab1315a4fa"
+
+DEPENDS = "optee-client-qoriq optee-os-qoriq python3-pycryptodome-native"
+
+inherit python3native
+
+SRC_URI = "git://github.com/OP-TEE/optee_test;nobranch=1"
+SRCREV = "30481e381cb4285706e7516853495a7699c93b2c"
+
+S = "${WORKDIR}/git"
+
+OPTEE_CLIENT_EXPORT = "${STAGING_DIR_HOST}${prefix}"
+TEEC_EXPORT         = "${STAGING_DIR_HOST}${prefix}"
+TA_DEV_KIT_DIR      = "${STAGING_INCDIR}/optee/export-user_ta"
+
+EXTRA_OEMAKE = " TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
+                 OPTEE_CLIENT_EXPORT=${OPTEE_CLIENT_EXPORT} \
+                 CFG_ARM64=y \
+                 CROSS_COMPILE_HOST=${TARGET_PREFIX} \
+                 CROSS_COMPILE_TA=${TARGET_PREFIX} \
+                 V=1 \
+               "
+
+do_compile() {
+    # Top level makefile doesn't seem to handle parallel make gracefully
+    oe_runmake xtest
+    oe_runmake ta
+}
+
+do_install () {
+    install -D -p -m0755 ${S}/out/xtest/xtest ${D}${bindir}/xtest
+
+    # install path should match the value set in optee-client/tee-supplicant
+    # default TEEC_LOAD_PATH is /lib
+    mkdir -p ${D}/lib/optee_armtz/
+    install -D -p -m0444 ${S}/out/ta/*/*.ta ${D}/lib/optee_armtz/
+}
+
+FILES_${PN} += "/lib/optee_armtz/"
+
+# Imports machine specific configs from staging to build
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(qoriq-arm64)"