optee-imx: upgrade to version 3.7.0

Update all recipes to pull sources from imx_5.4.24_2.1.0 branch in NXP
upstream and update SRCREV to match release tags.

Update PREFERRED_VERSION of optee for mx8 to point to 3.7.0.imx.

Following notes are additions to the version update of recipes:
--------------------------
optee-os:
- Refresh gcc10 patch to resolve the fuzz during apply
- Drop python patch as it is already applied upstream
- Add new machines to the list

optee-client:
- Update CFLAGS patch to match 3.7.0 version
- Split ${B} from ${S}, this makes build more clear

optee-test:
- Remove do_compile task and substitute with OEMAKE

Signed-off-by: Andrey Zhizhikin <andrey.z@gmail.com>

1 files changed, 55 insertions, 0 deletions

diff --git a/recipes-security/optee-imx/optee-test_3.7.0.imx.bb b/recipes-security/optee-imx/optee-test_3.7.0.imx.bb
new file mode 100644
index 00000000..04240ff0
--- /dev/null
+++ b/recipes-security/optee-imx/optee-test_3.7.0.imx.bb
@@ -0,0 +1,55 @@
+# Copyright (C) 2017-2018 NXP
+
+SUMMARY = "OPTEE test"
+HOMEPAGE = "http://www.optee.org/"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=daa2bcccc666345ab8940aab1315a4fa"
+
+DEPENDS = "optee-os optee-client python3-pycrypto-native openssl"
+inherit python3native
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+SRCBRANCH = "imx_5.4.24_2.1.0"
+
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-optee-test.git;protocol=https;branch=${SRCBRANCH} \
+           file://0001-use-python3-instead-of-python.patch \
+"
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/build"
+
+SRCREV = "227d6f4c40eaa6f84fe049b9e48c7b27ad7fab08"
+
+OPTEE_ARCH ?= "arm32"
+OPTEE_ARCH_armv7a = "arm32"
+OPTEE_ARCH_aarch64 = "arm64"
+
+TA_DEV_KIT_DIR_arm = "${STAGING_INCDIR}/optee/export-user_ta_arm32/"
+TA_DEV_KIT_DIR_aarch64 = "${STAGING_INCDIR}/optee/export-user_ta_arm64/"
+
+EXTRA_OEMAKE = " \
+    TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
+    ARCH=${OPTEE_ARCH} \
+    OPTEE_CLIENT_EXPORT=${STAGING_DIR_HOST}/usr \
+    CROSS_COMPILE_HOST=${HOST_PREFIX} \
+    CROSS_COMPILE_TA=${HOST_PREFIX} \
+    CROSS_COMPILE=${HOST_PREFIX} \
+    OPTEE_OPENSSL_EXPORT=${STAGING_INCDIR}/ \
+    -C ${S} O=${B} \
+"
+
+do_install () {
+        install -d ${D}/usr/bin
+        install ${B}/xtest/xtest ${D}/usr/bin/
+
+        install -d ${D}/lib/optee_armtz
+        find ${B}/ta -name '*.ta' | while read name; do
+                install -m 444 $name ${D}/lib/optee_armtz/
+        done
+}
+
+FILES_${PN} = "/usr/bin/ /lib*/optee_armtz/"
+
+COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"