Merge pull request #985 from thochstein/optee

Optee: Upgrade 3.10.0.imx -> 3.15.0.imx

1 files changed, 70 insertions, 0 deletions

diff --git a/recipes-security/optee-imx/optee-test_3.15.0.imx.bb b/recipes-security/optee-imx/optee-test_3.15.0.imx.bb
new file mode 100644
index 00000000..1d6de243
--- /dev/null
+++ b/recipes-security/optee-imx/optee-test_3.15.0.imx.bb
@@ -0,0 +1,70 @@
+# Copyright (C) 2017-2021 NXP
+
+SUMMARY = "OPTEE test"
+HOMEPAGE = "http://www.optee.org/"
+
+LICENSE = "BSD-2-Clause & GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=daa2bcccc666345ab8940aab1315a4fa"
+
+DEPENDS = "python3-pycryptodome-native python3-pycryptodomex-native optee-os optee-client openssl"
+
+SRCBRANCH = "lf-5.10.72_2.2.0"
+
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-optee-test.git;protocol=https;branch=${SRCBRANCH}"
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/build"
+
+SRCREV = "4d81b964a72e89a62d04187b3f055d8346b383c9"
+
+inherit python3native features_check
+
+REQUIRED_MACHINE_FEATURES = "optee"
+
+OPTEE_ARCH ?= "arm32"
+OPTEE_ARCH:armv7a = "arm32"
+OPTEE_ARCH:aarch64 = "arm64"
+
+TA_DEV_KIT_DIR:arm = "${STAGING_INCDIR}/optee/export-user_ta_arm32/"
+TA_DEV_KIT_DIR:aarch64 = "${STAGING_INCDIR}/optee/export-user_ta_arm64/"
+
+CFLAGS += "--sysroot=${STAGING_DIR_HOST}"
+CXXFLAGS += "--sysroot=${STAGING_DIR_HOST}"
+
+EXTRA_OEMAKE = " \
+    TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
+    ARCH=${OPTEE_ARCH} \
+    OPTEE_CLIENT_EXPORT=${STAGING_DIR_HOST}/usr \
+    CROSS_COMPILE_HOST=${HOST_PREFIX} \
+    CROSS_COMPILE_TA=${HOST_PREFIX} \
+    CROSS_COMPILE=${HOST_PREFIX} \
+    -C ${S} O=${B} \
+"
+
+do_compile() {
+    cd ${S}
+    # Top level makefile doesn't seem to handle parallel make gracefully
+    oe_runmake xtest
+    oe_runmake ta
+    oe_runmake test_plugin
+}
+do_compile[cleandirs] = "${B}"
+
+do_install () {
+        install -d ${D}${bindir}
+        install ${B}/xtest/xtest ${D}${bindir}
+
+        install -d ${D}${nonarch_base_libdir}/optee_armtz
+        find ${B}/ta -name '*.ta' | while read name; do
+                install -m 444 $name ${D}${nonarch_base_libdir}/optee_armtz/
+        done
+
+        install -d ${D}${libdir}/tee-supplicant/plugins/
+        install ${B}/supp_plugin/*plugin ${D}${libdir}/tee-supplicant/plugins/
+}
+
+FILES:${PN} += "${nonarch_base_libdir}/optee_armtz/ ${libdir}/tee-supplicant/plugins/"
+
+RDEPENDS:${PN} = "optee-os"
+
+COMPATIBLE_MACHINE = "(imx-nxp-bsp)"