imx-parser: upgrade to 4.5.5

NOTE: This version uses v11 EULA from NXP

Following commits are added in this release (including command):
$ git log --oneline --no-decorate eff47177..72395663
72395663 MA-17095: MP4 PARSER 06.16.07
6abeb330 MA-16391-2: MP4 PARSER 06.16.06
7a8c66d5 MA-16391: MP4 PARSER 06.16.05 support ENCRYPTED_BYTE_BLOCK, SKIP_BYTE_BLOCK, CRYPTO_IV
6f7d785f MA-17070 MP3 PARSER 03.03.03
8fb0fc1a MA-17026 AAC PARSER 03.01.04
8d04d6cd MA-16982: fix cts android.media.cts.DecoderTest#testDecodeMonoOggMkv
1bc9b758 MA-16969 [Android] Q10_2.0.0 cts MediaMuxerTest#testAllTimestampsBVideoOnly fail
efa3c12f MMFMWK-8754 MPEG2 PARSER 05.01.02
fbab3462 MA-16828: fix cts android.media.cts.DecoderTest#testTrackSelectionMkv
2e2ca2ad MA-16684: suppoert av1 video format in mkv parser
e9cf3560 [configurea.ac] Update version to 4.5.5 for next release
138ef113 MA-16403 Fix ID3 parser return wrong artwork size
782e91e1 MA-16375 MPEG2 PARSER 05.01.01
57207e77 MMFMWK-8725 MP3 PARSER 03.03.01
48581949 MMFMWK-8650 MPG2 PARSER 04.06.03
2f3da775 [configurea.ac] Update version to 4.5.4 for next release

Signed-off-by: Andrey Zhizhikin <andrey.zhizhikin@leica-geosystems.com>
Cc: Tom Hochstein <tom.hochstein@nxp.com>
(cherry picked from commit 10f3833c3cdba45d9c89bcf093e18791bb037556)

1 files changed, 46 insertions, 0 deletions

diff --git a/recipes-multimedia/imx-parser/imx-parser_4.5.5.bb b/recipes-multimedia/imx-parser/imx-parser_4.5.5.bb
new file mode 100644
index 00000000..ddc83aa2
--- /dev/null
+++ b/recipes-multimedia/imx-parser/imx-parser_4.5.5.bb
@@ -0,0 +1,46 @@
+# Copyright (C) 2012-2018 O.S. Systems Software LTDA.
+# Copyright (C) 2012-2016 Freescale Semiconductor
+# Copyright (C) 2017, 2019 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Freescale Multimedia parser libs"
+LICENSE = "Proprietary"
+SECTION = "multimedia"
+LIC_FILES_CHKSUM = "file://COPYING;md5=228c72f2a91452b8a03c4cab30f30ef9"
+
+# For backwards compatibility
+PROVIDES += "libfslparser"
+RREPLACES_${PN} = "libfslparser"
+RPROVIDES_${PN} = "libfslparser"
+RCONFLICTS_${PN} = "libfslparser"
+
+SRC_URI = "${FSL_MIRROR}/${BPN}-${PV}.bin;fsl-eula=true"
+SRC_URI[md5sum] = "0845c64d2b64c2822328e8bc8442f5b8"
+SRC_URI[sha256sum] = "33b8377a663b2ca749f40ef1164918335913e4de02a3857f2892707647d243de"
+
+inherit fsl-eula-unpack autotools pkgconfig
+
+# Choose between 32-bit and 64-bit binaries and between Soft Float-Point and Hard Float-Point
+EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '--enable-armv8', \
+                  bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '--enable-fsw', d), d)}"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+python __set_insane_skip() {
+    # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+    # the source we cannot fix it. Disable the insane check for now.
+    # FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
+    for p in d.getVar('PACKAGES').split():
+        d.setVar("INSANE_SKIP_%s" % p, "ldflags dev-so textrel")
+}
+
+do_package_qa[prefuncs] += "__set_insane_skip"
+
+# FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
+FILES_${PN} += "${libdir}/imx-mm/*/*${SOLIBS} ${libdir}/imx-mm/*/*${SOLIBSDEV}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+INHIBIT_SYSROOT_STRIP = "1"
+
+COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"