gstreamer1.0-plugins-imx: Upgrade to version 2.1.0

* meson:
  * New sysroot option in case the external sysroot property is unusable
    Normally, this option should not be needed. However, with some BSPs
    whose sysroot properties are broken, having this option is useful.
  * Reduce minimum required Meson version from 0.54.0 to 0.53.2
    This is mainly introduced for Yocto Dunfell support.
    (Meson <0.54 requires the new sysroot property though.)
  * Cleanup deprecated code

* imx2d: UYVY and YUYV formats are supported by G2D if it is emulated on
  top of the DPU (found in i.MX8 QuadMax and i.MX8 QuadXPlus SocS).

* vpu:
  * Correctly handle case when a stream buffer is not needed
  * Disable frame reordering if it is not needed
  * imxvpudec_h264 needs au alignment to guarantee complete frames
  * Unlock decoder_context on fatal error while decoding

* v4l2video:
  * v4l2videosrc: Skip allocation pools with NULL buffer pool
    Prevents assertions like:
    gst_buffer_pool_has_option: assertion 'GST_IS_BUFFER_POOL (pool)' failed
    See: https://github.com/Freescale/gstreamer-imx/issues/304
  * v4l2videosrc: Skip allocation params with NULL allocator
    Prevents assertions like:
    gst_object_unref: assertion 'object != NULL' failed
    See: https://github.com/Freescale/gstreamer-imx/issues/304
  * v4l2videosrc: Use correct ioctl for frame intervals
  * Minor logging fixes

Signed-off-by: Carlos Rafael Giani <crg7475@mailbox.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_2.1.0.bb b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_2.1.0.bb
new file mode 100644
index 00000000..fb18f1bb
--- /dev/null
+++ b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-imx_2.1.0.bb
@@ -0,0 +1,62 @@
+# Copyright (C) 2018 O.S. Systems Software LTDA.
+DESCRIPTION = "GStreamer 1.0 plugins for i.MX platforms"
+LICENSE = "LGPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=55ca817ccb7d5b5b66355690e9abc605"
+SECTION = "multimedia"
+DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base libimxdmabuffer"
+# add the audioparsers and the videoparsersbad plugins as RDEPENDS ; audioparsers
+# for the uniaudio decoder, videoparsersbad for the VPU video decoder
+# the gstreamer1.0-plugins-imx RDEPENDS is necessary to ensure the -good recipe is
+# built (it is not a compile-time dependency however, hence RDEPENDS and not DEPENDS)
+RDEPENDS:gstreamer1.0-plugins-imx = "gstreamer1.0-plugins-good gstreamer1.0-plugins-bad"
+RDEPENDS:gstreamer1.0-plugins-imx-imxaudio = "gstreamer1.0-plugins-good-audioparsers"
+RDEPENDS:gstreamer1.0-plugins-imx-imxvpu = "gstreamer1.0-plugins-bad-videoparsersbad"
+
+PV .= "+git${SRCPV}"
+
+SRCBRANCH ?= "master"
+SRCREV = "b1e5cca1a6df9d2c0dc505ae222775798108d340"
+SRC_URI = "git://github.com/Freescale/gstreamer-imx.git;branch=${SRCBRANCH};protocol=https"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig meson use-imx-headers
+
+# libg2d on i.MX8 SoCs with a DPU is emulated via the DPU.
+# That particular libg2d .so depends on libdrm, however.
+# Also, due to behavioral differences, an additional flag
+# is needed to improve performance.
+LIBG2D_DPU_OPTION = "-Dg2d-based-on-dpu=false"
+LIBG2D_DEPENDENCIES = "virtual/libg2d"
+LIBG2D_DPU_OPTION:imxdpu = "-Dg2d-based-on-dpu=true"
+LIBG2D_DEPENDENCIES:imxdpu = "virtual/libg2d libdrm"
+
+EXTRA_OEMESON += "-Dimx-headers-path=${STAGING_INCDIR_IMX}"
+
+PACKAGECONFIG ?= "uniaudiodec"
+PACKAGECONFIG:append:imxgpu2d = " g2d"
+PACKAGECONFIG:append:imxvpu   = " vpu"
+PACKAGECONFIG:append:imxipu   = " ipu"
+PACKAGECONFIG:append:imxpxp   = " pxp"
+# The custom imxv4l2 elements are only available on the i.MX6.
+# The 2D blitter sinks require an MXC framebuffer, which
+# is not available anymore on the i.MX8 (since these SoCs
+# now use KMS instead of the old Linux framebuffer).
+PACKAGECONFIG:append:mx6-nxp-bsp      = " imx2dvideosink v4l2"
+PACKAGECONFIG:append:mx7-nxp-bsp      = " imx2dvideosink"
+
+PACKAGECONFIG[g2d] = "-Dg2d=enabled ${LIBG2D_DPU_OPTION},-Dg2d=disabled,${LIBG2D_DEPENDENCIES}"
+PACKAGECONFIG[pxp] = "-Dpxp=enabled,-Dpxp=disabled,"
+PACKAGECONFIG[ipu] = "-Dipu=enabled,-Dipu=disabled,"
+PACKAGECONFIG[vpu] = "-Dvpu=enabled,-Dvpu=disabled,libimxvpuapi2"
+PACKAGECONFIG[imx2dvideosink] = "-Dimx2d-videosink=true,-Dimx2d-videosink=false,"
+PACKAGECONFIG[v4l2] = "-Dv4l2=true,-Dv4l2=false,"
+PACKAGECONFIG[uniaudiodec] = "-Duniaudiodec=enabled,-Duniaudiodec=disabled,imx-codec"
+PACKAGECONFIG[mp3encoder] = "-Dmp3encoder=enabled,-Dmp3encoder=disabled,imx-codec"
+
+require recipes-multimedia/gstreamer/gstreamer1.0-plugins-packaging.inc
+
+# the following line is required to produce one package for each plugin
+PACKAGES_DYNAMIC = "^${PN}-.*"
+
+COMPATIBLE_MACHINE = "(mx6dl-nxp-bsp|mx6q-nxp-bsp|mx6sl-nxp-bsp|mx6sx-nxp-bsp|mx6ul-nxp-bsp|mx6ull-nxp-bsp|mx7d-nxp-bsp|mx8-nxp-bsp)"