linux-qoriq/4.14: add recipes

*Change:
dfe1b13 - Merge branch 'linux-4.14-nxp' into linux-4.14 on Mar. 10, 2018
49052dd - driver: mtd: ifc: increase eccstat array size for ver >= 2.0.0
8868a66 - staging: fsl_ppfe/eth: calculate PFE_PKT_SIZE with SKB_DATA_ALIGN
5d3108f - Merge branch 'linux-4.14-nxp' into linux-4.14 on Mar. 9, 2018
00499bc - fsl-mc/dpio: aligned access of qbman cacheable region
c6dc266 - Revert "arm64: Increase the max granular size"
162a1c2 - Revert "drm/fsl-dcu: Fix DCU pixel clock issue in suspend/resume functions"
c0f10fd - Revert "drm/fsl-dcu: Fix the interrupt issue in suspend/resume functions"
9fa638a - Merge branch 'linux-4.14-nxp' into linux-4.14 on Mar. 8, 2018
8a1a783 - fsl/fman: add dpaa in module names
15efaa7 - Revert "fsl/man: Inherit parent device and of_node"
71b24fe - dpaa_eth: workaround for ERR010022
610d7ad - arm64: dts: ls208x: remove NXP Erratum A008585 from LS2088A.
743dacb - arm: dts: ls1021a: correct the register range of dcfg
3401072 - Merge branch 'linux-4.14-nxp' into linux-4.14 for the first time
bf6f273 - usb: fsl: Fix compilation error
1c103ed - USB3/DWC3: Add property "snps,incr-burst-type-adjustment" for INCR burst type
8160631 - arm: configs: Enable CONFIG_MTD_CFI_AMDSTD and CONFIG_MTD_PHYSMAP_OF.
6fd0fad - arm: configs: re-arrangement of configs due to savedefconfig.
ef83478 - dma: caam: add dma memcpy driver
e4d7155 - staging: fsl-dpaa2/ethsw: Refactor setting TCI
a754c94 - driver: mtd: fsl_qspi: Remap QSPI address space for LS1088 and LS2088
e663062 - drivers: mtd: fsl_qspi: Reserve LUT for AHB read
3960ac8 - arm64: Allocate elfcorehdr & crashkernel mem before any reservation
a761fda - staging: fsl-dpaa2/eth: Guard call to bpf_prog_run_xdp
54dfa72 - arm: dts: ls1021a: Add configure-gfladj property to USB3 node
63f536f - crypto: caam/qi2 - fix probing order dependencies
9f55ce5 - arm:configs: Add lttng.config to support LTTng modules
b994964 - arm64:configs: Add lttng.config to support LTTng modules
efcd706 - arm/arm64: KVM : do not change mapping bits for hugepages
328e23c - samples/bpf: Use getppid instead of getpgrp for array map stress
91e103c - bpf: Add -target to clang switch while cross compiling.
8a3cfaf - samples/bpf: Fix pt_regs issues when cross-compiling
090d4d0 - samples/bpf: Enable cross compiler support
78d165b - dmaengine: dmatest: fix dmatest calltrace error
18bf3d1 - staging: fsl-mc: set coherent dma mask in devices on fsl-mc bus
b6ae88c - arm64: dts: update the cpu idle node

Signed-off-by: Chunrong Guo <chunrong.guo@nxp.com>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 63 insertions, 0 deletions

diff --git a/recipes-kernel/linux/linux-qoriq_4.14.bb b/recipes-kernel/linux/linux-qoriq_4.14.bb
new file mode 100644
index 00000000..0a708fe1
--- /dev/null
+++ b/recipes-kernel/linux/linux-qoriq_4.14.bb
@@ -0,0 +1,63 @@
+inherit kernel qoriq_build_64bit_kernel
+inherit fsl-kernel-localversion
+
+SUMMARY = "Linux Kernel for NXP QorIQ platforms"
+SECTION = "kernel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/linux;nobranch=1 \
+"
+SRCREV = "dfe1b1320d85c5eea99af54dfbf5e9923c3392cc"
+
+S = "${WORKDIR}/git"
+
+DEPENDS_append = " libgcc"
+# not put Images into /boot of rootfs, install kernel-image if needed
+RDEPENDS_${KERNEL_PACKAGE_NAME}-base = ""
+
+KERNEL_CC_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_LD_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
+
+ZIMAGE_BASE_NAME = "zImage-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
+ZIMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
+
+SCMVERSION ?= "y"
+LOCALVERSION = ""
+DELTA_KERNEL_DEFCONFIG ?= ""
+DELTA_KERNEL_DEFCONFIG_prepend_qoriq-arm64 = "lsdk.config "
+DELTA_KERNEL_DEFCONFIG_prepend_fsl-lsch2-32b = "multi_v7_lpae.config multi_v8.config lsdk.config "
+DELTA_KERNEL_DEFCONFIG_prepend_ls102xa = "multi_v7_lpae.config lsdk.config "
+
+do_merge_delta_config[dirs] = "${B}"
+
+do_merge_delta_config() {
+    # create config with make config
+    oe_runmake  -C ${S} O=${B} ${KERNEL_DEFCONFIG}
+    
+    # add config fragments
+    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
+        if [ -f ${S}/arch/${ARCH}/configs/${deltacfg} ]; then
+            oe_runmake  -C ${S} O=${B} ${deltacfg}
+        elif [ -f "${WORKDIR}/${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
+        elif [ -f "${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
+        fi
+    done
+    cp .config ${WORKDIR}/defconfig
+}
+addtask merge_delta_config before do_preconfigure after do_patch
+
+# The link of dts folder is needed for 32b compile of aarch64 targets(e.g. ls1043ardb-32b)
+do_compile_prepend_fsl-lsch2-32b() {
+    ln -sfT ${STAGING_KERNEL_DIR}/arch/arm64/boot/dts/freescale ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
+}
+
+do_install_prepend_fsl-lsch2-32b() {
+    rm -f ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
+}
+
+FILES_${KERNEL_PACKAGE_NAME}-image += "/boot/zImage*"
+COMPATIBLE_MACHINE = "(qoriq)"