Move meta-fsl-arm content to layer root

The meta-fsl-arm is going to be used as the base for this layer. It
contains a clean history and allowing a more granullar set of changes.

This commit is just a rename of all contents of meta-fsl-arm
subdirectory to this layer's root, subsequent changes are based on top
of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

7 files changed, 260 insertions, 0 deletions

diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb
new file mode 100644
index 00000000..ecf38f2f
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-bin-mx51_11.09.01.bb
@@ -0,0 +1,13 @@
+# Copyright (C) 2011, 2012 Freescale
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "GPU driver and apps for frambuffer on mx51"
+
+include amd-gpu-mx51.inc
+
+SRC_URI[md5sum] = "9f9b5f67b595721a08793aae8bd8fc46"
+SRC_URI[sha256sum] = "f0db68a764b5fb199729e7435f606b8d12b61ca97990336c647b7e81f4a584d9"
+
+RCONFLICTS_${PN} = "amd-gpu-x11-bin-mx51"
+
+COMPATIBLE_MACHINE = "(mx5)"
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc
new file mode 100644
index 00000000..76c7bc43
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-mx51.inc
@@ -0,0 +1,110 @@
+# Copyright (C) 2011, 2012, 2013 Freescale
+# Copyright (C) 2011-2015 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+LICENSE = "Proprietary"
+SECTION = "libs"
+
+# FIXME: Replace for correct AMD license
+LIC_FILES_CHKSUM = "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
+
+PROVIDES = "amd-gpu-mx51 virtual/egl virtual/libgles1 virtual/libgles2"
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true \
+           file://egl.pc \
+           file://glesv2.pc \
+           file://fix-linux-build-check.patch"
+
+inherit fsl-eula-unpack
+
+# For the packages that make up the OpenGL interfaces, inject variables so that
+# they don't get Debian-renamed (which would remove the -mx51 suffix).
+#
+# FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+# the source we cannot fix it. Disable the insane check for now.
+python __anonymous() {
+    for p in d.getVar('PACKAGES', True).split():
+        d.setVar("INSANE_SKIP_%s" % p, "ldflags")
+
+    for p in (("libegl", "libegl1"), ("libgl", "libgl1"),
+              ("libgles2", "libglesv2-2")):
+        fullp = p[0] + "-mx51"
+        pkgs = " ".join(p)
+        d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
+        d.appendVar("RREPLACES_" + fullp, pkgs)
+        d.appendVar("RPROVIDES_" + fullp, pkgs)
+        d.appendVar("RCONFLICTS_" + fullp, pkgs)
+
+        # For -dev, the first element is both the Debian and original name
+        fullp += "-dev"
+        pkgs = p[0] + "-dev"
+        d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
+        d.appendVar("RREPLACES_" + fullp, pkgs)
+        d.appendVar("RPROVIDES_" + fullp, pkgs)
+        d.appendVar("RCONFLICTS_" + fullp, pkgs)
+}
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${bindir}
+    install -d ${D}${includedir}
+
+    cp -Pr ${S}/usr/bin/* ${D}${bindir}
+    cp -Pr ${S}/usr/lib/* ${D}${libdir}
+    cp -Pr ${S}/usr/include/* ${D}${includedir}
+
+    find ${D}${bindir} -type f -exec chmod 755 {} \;
+    find ${D}${libdir} -type f -exec chmod 644 {} \;
+    find ${D}${includedir} -type f -exec chmod 644 {} \;
+
+    # FIXME: Fix sonames of broken libraries
+    mv ${D}${libdir}/lib2dz160.so ${D}${libdir}/lib2dz160.so.0
+    mv ${D}${libdir}/lib2dz430.so ${D}${libdir}/lib2dz430.so.0
+    ln -sf lib2dz160.so.0 ${D}${libdir}/lib2dz160.so
+    ln -sf lib2dz430.so.0 ${D}${libdir}/lib2dz430.so
+
+    # FIXME: Remove unknown files
+    rm -r ${D}${libdir}/libcsi.a \
+          ${D}${libdir}/libres.a
+
+    # FIXME: Add pkgconfig files
+    install -d ${D}${libdir}/pkgconfig
+    install -m 644 ${WORKDIR}/egl.pc ${D}${libdir}/pkgconfig
+    install -m 644 ${WORKDIR}/glesv2.pc ${D}${libdir}/pkgconfig
+}
+
+PACKAGES =+ "libgsl-fsl-mx51 libgsl-fsl-mx51-dev libgsl-fsl-mx51-dbg \
+             libegl-mx51 libegl-mx51-dev libegl-mx51-dbg \
+             libgles-mx51 libgles-mx51-dev libgles-mx51-dbg \
+             libgles2-mx51 libgles2-mx51-dev libgles2-mx51-dbg \
+             libopenvg-mx51 libopenvg-mx51-dev libopenvg-mx51-dbg \
+             lib2dz160-mx51 lib2dz160-mx51-dbg \
+             lib2dz430-mx51 lib2dz430-mx51-dbg"
+
+FILES_${PN}-dbg = "${bindir}/.debug/*"
+
+FILES_libgsl-fsl-mx51 = "${libdir}/libgsl-fsl${SOLIBS}"
+FILES_libgsl-fsl-mx51-dev = "${libdir}/libgsl-fsl${SOLIBSDEV}"
+FILES_libgsl-fsl-mx51-dbg = "${libdir}/.debug/libgsl-fsl${SOLIBS}"
+
+FILES_libegl-mx51 = "${libdir}/libEGL${SOLIBS}"
+FILES_libegl-mx51-dev = "${includedir}/EGL ${includedir}/KHR ${libdir}/libEGL${SOLIBSDEV}"
+FILES_libegl-mx51-dbg = "${libdir}/.debug/libEGL${SOLIBS}"
+
+FILES_libgles-mx51 = "${libdir}/libGLESv1*${SOLIBS}"
+FILES_libgles-mx51-dev = "${includedir}/GLES ${libdir}/libGLESv1*${SOLIBSDEV}"
+FILES_libgles-mx51-dbg = "${libdir}/.debug/libGLESv1*${SOLIBS}"
+
+FILES_libgles2-mx51 = "${libdir}/libGLESv2${SOLIBS}"
+FILES_libgles2-mx51-dev = "${includedir}/GLES2 ${libdir}/libGLESv2${SOLIBSDEV}"
+FILES_libgles2-mx51-dbg = "${libdir}/.debug/libGLESv2${SOLIBS}"
+
+FILES_libopenvg-mx51 = "${libdir}/libOpenVG${SOLIBS}"
+FILES_libopenvg-mx51-dev = "${includedir}/VG ${libdir}/libOpenVG${SOLIBSDEV}"
+FILES_libopenvg-mx51-dbg = "${libdir}/.debug/libOpenVG${SOLIBS}"
+
+FILES_lib2dz160-mx51 = "${libdir}/lib2dz160${SOLIBS}"
+FILES_lib2dz160-mx51-dbg = "${libdir}/.debug/lib2dz160${SOLIBS}"
+
+FILES_lib2dz430-mx51 = "${libdir}/lib2dz430${SOLIBS}"
+FILES_lib2dz430-mx51-dbg = "${libdir}/.debug/lib2dz430${SOLIBS}"
diff --git a/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
new file mode 100644
index 00000000..7fc351b0
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/amd-gpu-x11-bin-mx51_11.09.01.bb
@@ -0,0 +1,25 @@
+# Copyright (C) 2011-2015 O.S. Systems Software LTDA.
+# Copyright (C) 2011, 2012 Freescale
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "GPU driver and apps for x11 on mx51"
+PR = "r12"
+
+# FIXME: Replace for correct AMD license
+LIC_FILES_CHKSUM = "file://usr/include/VG/openvg.h;endline=30;md5=b0109611dd76961057d4c45ae6519802"
+DEPENDS = "virtual/libx11 libxrender libxext"
+
+include amd-gpu-mx51.inc
+
+SRC_URI[md5sum] = "54391a4e670b597d06d01253fb217cad"
+SRC_URI[sha256sum] = "c7a6fa03b7aa2a375556c59908876554ba720c1e744baba2debb84a408f790db"
+
+RCONFLICTS_${PN} = "amd-gpu-bin-mx51"
+
+COMPATIBLE_MACHINE = "${@base_contains('DISTRO_FEATURES', 'x11', '(mx5)', 'Invalid!', d)}"
+
+do_install_append() {
+    # eglplatform_1.4.h contains X11 compatible headers
+    rm ${D}${includedir}/EGL/eglplatform.h
+    mv ${D}${includedir}/EGL/eglplatform_1.4.h ${D}${includedir}/EGL/eglplatform.h
+}
diff --git a/recipes-graphics/amd-gpu-x11-bin/files/egl.pc b/recipes-graphics/amd-gpu-x11-bin/files/egl.pc
new file mode 100644
index 00000000..3d2ab5db
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/files/egl.pc
@@ -0,0 +1,11 @@
+prefix=/usr
+exec_prefix=${prefix}
+libdir=/usr/lib
+includedir=/usr/include
+
+Name: egl
+Description: AMD EGL library
+Requires.private:
+Version: 8.0
+Libs: -L${libdir} -lEGL
+Cflags: -I${includedir}
diff --git a/recipes-graphics/amd-gpu-x11-bin/files/fix-linux-build-check.patch b/recipes-graphics/amd-gpu-x11-bin/files/fix-linux-build-check.patch
new file mode 100644
index 00000000..946bfac7
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/files/fix-linux-build-check.patch
@@ -0,0 +1,54 @@
+diff -Nur amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/EGL/eglext.h amd-gpu-x11-bin-mx51-11.09.01/usr/include/EGL/eglext.h
+--- amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/EGL/eglext.h 2012-08-18 12:43:19.431788396 -0300
++++ amd-gpu-x11-bin-mx51-11.09.01/usr/include/EGL/eglext.h      2012-08-18 12:43:50.799909873 -0300
+@@ -164,11 +164,11 @@
+  * nanoseconds (unadjusted standard time).  Here, it is defined as
+  * appropriate for an ISO C compiler.
+  */
+-#ifndef _LINUX
++#ifndef __linux__
+ typedef uint64_t EGLTimeKHR;
+-#else   // _LINUX
++#else   // __linux__
+ typedef unsigned long long EGLTimeKHR;
+-#endif  // _LINUX
++#endif  // __linux__
+ 
+ #define EGL_SYNC_PRIOR_COMMANDS_COMPLETE_KHR            0xFFF8
+ #define EGL_SYNC_STATUS_KHR                             0xFFF7                                  
+diff -Nur amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/EGL/eglfslext.h amd-gpu-x11-bin-mx51-11.09.01/usr/include/EGL/eglfslext.h
+--- amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/EGL/eglfslext.h      2012-08-18 12:43:19.431788396 -0300
++++ amd-gpu-x11-bin-mx51-11.09.01/usr/include/EGL/eglfslext.h   2012-08-18 12:43:50.759785714 -0300
+@@ -65,7 +65,7 @@
+ } eglYUVInfo;
+ #endif
+ 
+-#ifdef _LINUX
++#ifdef __linux__
+ struct EGLImageInfoFSL
+ {
+     void *mem_virt[3]; //virtual addresses for Y/U/V planes
+diff -Nur amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/VG/ext.h amd-gpu-x11-bin-mx51-11.09.01/usr/include/VG/ext.h
+--- amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/VG/ext.h     2012-08-18 12:43:19.431788396 -0300
++++ amd-gpu-x11-bin-mx51-11.09.01/usr/include/VG/ext.h  2012-08-18 12:43:50.799909873 -0300
+@@ -15,7 +15,7 @@
+ extern "C" {
+ #endif
+ 
+-#ifndef _LINUX
++#ifndef __linux__
+ #include <VG/openvg.h>
+ #else
+ #include "openvg.h"
+diff -Nur amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/VG/openvg.h amd-gpu-x11-bin-mx51-11.09.01/usr/include/VG/openvg.h
+--- amd-gpu-x11-bin-mx51-11.09.01.orig/usr/include/VG/openvg.h  2012-08-18 12:43:19.431788396 -0300
++++ amd-gpu-x11-bin-mx51-11.09.01/usr/include/VG/openvg.h       2012-08-18 12:43:50.799909873 -0300
+@@ -449,7 +449,7 @@
+ #       endif
+ #   elif defined(__APPLE__)
+ #       define VG_API_CALL extern
+-#   elif defined(_LINUX)
++#   elif defined(__linux__)
+ #       if defined (OPENVG_DLL_EXPORTS)
+ #           define VG_API_CALL extern
+ #       else
diff --git a/recipes-graphics/amd-gpu-x11-bin/files/glesv2.pc b/recipes-graphics/amd-gpu-x11-bin/files/glesv2.pc
new file mode 100644
index 00000000..62e1cb65
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/files/glesv2.pc
@@ -0,0 +1,11 @@
+prefix=/usr
+exec_prefix=${prefix}
+libdir=/usr/lib
+includedir=/usr/include
+
+Name: glesv2
+Description: AMD OpenGL ES 2.0 library
+Requires.private:
+Version: 8.0
+Libs: -L${libdir} -lGLESv2 -lEGL
+Cflags: -I${includedir}
diff --git a/recipes-graphics/amd-gpu-x11-bin/libz160_11.09.01.bb b/recipes-graphics/amd-gpu-x11-bin/libz160_11.09.01.bb
new file mode 100644
index 00000000..43b9f7ff
--- /dev/null
+++ b/recipes-graphics/amd-gpu-x11-bin/libz160_11.09.01.bb
@@ -0,0 +1,36 @@
+# Copyright (C) 2011-2015 O.S. Systems Software LTDA.
+# Copyright (C) 2011, 2012 Freescale
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "AMD libz160 gpu driver"
+LICENSE = "Proprietary"
+SECTION = "libs"
+DEPENDS = "amd-gpu-mx51"
+
+PR = "r2"
+
+#todo: Replace for correct AMD license
+LIC_FILES_CHKSUM = "file://usr/include/z160.h;endline=28;md5=65dd44cd769091092f38e34cd52cc271"
+
+SRC_URI = "${FSL_MIRROR}/libz160-bin-${PV}.bin;fsl-eula=true"
+SRC_URI[md5sum] = "9a9c2c93f4b44e89316772d348eead7d"
+SRC_URI[sha256sum] = "08767eb269a0a30ca0aa3d3b5aa9a53a2d17ed1c24651b7e8cefc7704b883f19"
+
+inherit fsl-eula-unpack
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    install -m 0755 ${S}/usr/lib/* ${D}${libdir}
+    install -m 0644 ${S}/usr/include/* ${D}${includedir}
+}
+
+S = "${WORKDIR}/${PN}-bin-${PV}"
+
+# Avoid QA Issue: No GNU_HASH in the elf binary
+INSANE_SKIP_${PN} = "ldflags"
+INSANE_SKIP_${PN}-dev = "ldflags"
+FILES_${PN} = "${libdir}/*.so"
+FILES_${PN}-dev = "${includedir}"
+
+COMPATIBLE_MACHINE = "(mx5)"