Move meta-fsl-ppc content to layer root

This commit is just a rename of all contents of meta-fsl-ppc
subdirectory to this layer's root, merging the contents of common
files, subsequent changes are based on top of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

8 files changed, 308 insertions, 0 deletions

diff --git a/recipes-dpaa/dpa-offload/dpa-offload_git.bb b/recipes-dpaa/dpa-offload/dpa-offload_git.bb
new file mode 100644
index 00000000..73809e26
--- /dev/null
+++ b/recipes-dpaa/dpa-offload/dpa-offload_git.bb
@@ -0,0 +1,49 @@
+DESCRIPTION = "Data-Path Acceleration Architecture Offloading User-Space Drivers"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c03ebb7a330b209986517466c74da72c"
+
+inherit pkgconfig
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "usdpaa fmlib"
+DEPENDS_append_b4860qds = " ipc-ust"
+DEPENDS_append_b4420qds = " ipc-ust"
+
+RDEPENDS_${PN} = "libgcc bash"
+RDEPENDS_${PN}_append_b4860qds = " ipc-ust"
+RDEPENDS_${PN}_append_b4420qds = " ipc-ust"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/usdpaa/dpa-offload.git;nobranch=1"
+SRCREV = "ed6191db9439d1aaba27fc01238da770d1d8ef9e"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${LD}"'
+export ARCH="${TARGET_ARCH}"
+
+PARALLEL_MAKE_pn-${PN} = ""
+
+FMAN_VARIANT ?= "P4080"
+FMAN_VARIANT_b4 = "FMAN_V3H"
+FMAN_VARIANT_t1 = "FMAN_V3L"
+FMAN_VARIANT_t2 = "FMAN_V3H"
+FMAN_VARIANT_t4 = "FMAN_V3H"
+FMAN_VARIANT_p1023rdb = "P1023"
+
+do_compile_prepend () {
+    export USDPAA_CFLAGS="-I ${STAGING_INCDIR}/usdpaa"
+    export FMLIB_CFLAGS="-I ${STAGING_INCDIR}/fmd \
+        -I ${STAGING_INCDIR}/fmd/Peripherals \
+        -I ${STAGING_INCDIR}/fmd/integrations \
+        -D${FMAN_VARIANT} -DNCSW_LINUX"
+}
+
+do_install () {
+    oe_runmake install DESTDIR=${D}
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
diff --git a/recipes-dpaa/eth-config/eth-config_git.bb b/recipes-dpaa/eth-config/eth-config_git.bb
new file mode 100644
index 00000000..32ef1fa2
--- /dev/null
+++ b/recipes-dpaa/eth-config/eth-config_git.bb
@@ -0,0 +1,17 @@
+DESCRIPTION = "Ethernet Configuration Files"
+SECTION = "eth-config"
+LICENSE = "BSD & GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8ed5eddbfbb84af5089ea94c382d423c"
+
+PR = "r2"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/eth-config.git;branch=master"
+SRCREV = "1d6ad160fda9123e93c65141aa1578b6253ff7bc"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "D=${D}"
+
+do_install() {
+    oe_runmake install
+}
diff --git a/recipes-dpaa/flib/flib_git.bb b/recipes-dpaa/flib/flib_git.bb
new file mode 100644
index 00000000..3818ccf8
--- /dev/null
+++ b/recipes-dpaa/flib/flib_git.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "Foundation Library"
+SECTION = "flib"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=75d2f6a74299640c05ae6c69ed7a4ad6"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/flib.git;nobranch=1"
+SRCREV = "91bbb134df1cd8b65c7c19db9bec9f00d1435377"
+
+S = "${WORKDIR}/git"
+
+do_install(){
+    oe_runmake install DESTDIR=${D}
+}
+
+ALLOW_EMPTY_${PN} = "1"
diff --git a/recipes-dpaa/fm-ucode/fm-ucode_git.bb b/recipes-dpaa/fm-ucode/fm-ucode_git.bb
new file mode 100644
index 00000000..52c79db8
--- /dev/null
+++ b/recipes-dpaa/fm-ucode/fm-ucode_git.bb
@@ -0,0 +1,38 @@
+DESCRIPTION = "Fman microcode binary"
+SECTION = "fm-ucode"
+LICENSE = "Freescale-EULA"
+LIC_FILES_CHKSUM = "file://EULA;md5=60037ccba533a5995e8d1a838d85799c"
+
+PR = "r1"
+
+inherit deploy
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fm-ucode.git;nobranch=1"
+SRCREV = "2827f0054e125b634fb1701719ca31c7d068e335"
+
+S = "${WORKDIR}/git"
+
+REGLEX ?= "${MACHINE}"
+REGLEX_t1023 = "t1024"
+REGLEX_t1040 = "t1040"
+REGLEX_t1042 = "t1040"
+REGLEX_b4420 = "b4860"
+REGLEX_t4160 = "t4240"
+
+do_install () {
+    UCODE=`echo ${REGLEX} | sed -e 's,-.*$,,' -e 's,[a-zA-Z]*$,,'`
+    install -d ${D}/boot
+    install -m 644 fsl_fman_ucode_${UCODE}*.bin ${D}/boot/
+}
+
+do_deploy () {
+    UCODE=`echo ${REGLEX} | sed -e 's,-.*$,,' -e 's,[a-zA-Z]*$,,'`
+    install -d ${DEPLOYDIR}/
+    install -m 644 fsl_fman_ucode_${UCODE}*.bin ${DEPLOYDIR}/
+}
+addtask deploy before do_build after do_install
+
+PACKAGES += "${PN}-image"
+FILES_${PN}-image += "/boot"
+ALLOW_EMPTY_${PN} = "1"
+COMPATIBLE_MACHINE = "(p1023rdb|e500mc|e5500|e5500-64b|e6500|e6500-64b)"
diff --git a/recipes-dpaa/fmc/fmc_git.bb b/recipes-dpaa/fmc/fmc_git.bb
new file mode 100644
index 00000000..f9bd74f6
--- /dev/null
+++ b/recipes-dpaa/fmc/fmc_git.bb
@@ -0,0 +1,52 @@
+DESCRIPTION = "Frame Manager Configuration tool"
+SECTION = "fmc"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a504ab5a8ff235e67c7301214749346c"
+
+PR = "r2"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fmc.git;nobranch=1"
+SRCREV = "b9e52be1f62a5fcc912d44875bf155ad55650d68"
+
+DEPENDS = "libxml2 fmlib tclap"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+EXTRA_OEMAKE_virtclass-native = 'FMCHOSTMODE=1 FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+
+PARALLEL_MAKE = ""
+
+EXTRA_OEMAKE_PLATFORM ?= ""
+EXTRA_OEMAKE_PLATFORM_b4 = "b4860qds"
+EXTRA_OEMAKE_PLATFORM_t2 = "b4860qds"
+EXTRA_OEMAKE_PLATFORM_t4 = "b4860qds"
+EXTRA_OEMAKE_PLATFORM_t1 = "t1040qds"
+
+do_compile () {
+    oe_runmake MACHINE=${EXTRA_OEMAKE_PLATFORM} -C source
+}
+
+do_install () {
+    install -d ${D}/${bindir}
+    install -m 755 ${S}/source/fmc ${D}/${bindir}/fmc
+
+    install -d ${D}/etc/fmc/config
+    install -m 644 ${S}/etc/fmc/config/hxs_pdl_v3.xml ${D}/etc/fmc/config
+
+    install -d ${D}/${includedir}/fmc
+    install ${S}/source/fmc.h ${D}/${includedir}/fmc
+
+    install -d ${D}/${libdir}
+    install ${S}/source/libfmc.a ${D}/${libdir}
+}
+
+BBCLASSEXTEND = "native"
diff --git a/recipes-dpaa/fmlib/fmlib_git.bb b/recipes-dpaa/fmlib/fmlib_git.bb
new file mode 100644
index 00000000..8993f848
--- /dev/null
+++ b/recipes-dpaa/fmlib/fmlib_git.bb
@@ -0,0 +1,45 @@
+DESCRIPTION = "Frame Manager User Space Library"
+SECTION = "fman"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3f16fa8e677e45af3127c5c4bafc3c00"
+
+PR = "r1"
+
+DEPENDS += "virtual/kernel"
+DEPENDS_virtclass-native = ""
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fmlib.git;nobranch=1"
+SRCREV = "4938e099561d441c947d4ccdf2e601ab2966d8cc"
+
+S = "${WORKDIR}/git"
+
+TARGET_ARCH_FMLIB = "${DEFAULTTUNE}"
+TARGET_ARCH_FMLIB_e5500 = "ppc32e5500"
+TARGET_ARCH_FMLIB_e6500 = "ppc32e6500"
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
+
+EXTRA_OEMAKE = "DESTDIR=${D} PREFIX=${prefix} LIB_DEST_DIR=${libdir} \
+        CROSS_COMPILE=${TARGET_PREFIX} KERNEL_SRC=${STAGING_KERNEL_DIR}"
+
+FMLIB_TARGET = "libfm-${TARGET_ARCH_FMLIB}"
+FMLIB_TARGET_t1 = "libfm-${TARGET_ARCH_FMLIB}-fmv3l"
+do_compile () {
+    oe_runmake ${FMLIB_TARGET}.a
+}
+
+do_compile_virtclass-native () {
+}
+
+do_install () {
+    oe_runmake install-${FMLIB_TARGET}
+}
+
+do_install_virtclass-native () {
+    install -d ${D}/${includedir}
+    cp -rf ${S}/include/* ${D}/${includedir}
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+BBCLASSEXTEND = "native"
diff --git a/recipes-dpaa/usdpaa-apps/usdpaa-apps_git.bb b/recipes-dpaa/usdpaa-apps/usdpaa-apps_git.bb
new file mode 100644
index 00000000..cf7910b8
--- /dev/null
+++ b/recipes-dpaa/usdpaa-apps/usdpaa-apps_git.bb
@@ -0,0 +1,65 @@
+DESCRIPTION = "User-Space Data-Path Acceleration Architecture Demo Applications"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://Makefile;endline=30;md5=d2a5d894118910d49993347f3f6e0f1e"
+
+inherit pkgconfig
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "libxml2 libedit ncurses readline fmc usdpaa dpa-offload libnl"
+DEPENDS_append_b4860qds = " ipc-ust"
+DEPENDS_append_b4420qds = " ipc-ust"
+
+RDEPENDS_${PN} = "libgcc bash"
+RDEPENDS_${PN}_append_b4860qds = " ipc-ust"
+RDEPENDS_${PN}_append_b4420qds = " ipc-ust"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/usdpaa/usdpaa-apps;nobranch=1"
+SRCREV = "95744440cf214d73884c44c0dbc296e1e4b4c8f4"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${LD}" AR="${AR}"'
+export ARCH="${TARGET_ARCH}"
+
+SOC ?= "P4080"
+SOC_b4 = "B4860"
+SOC_t1 = "T1040"
+SOC_t2 = "T2080"
+SOC_t4 = "T4240"
+SOC_p1023rdb = "P1023"
+
+FMAN_VARIANT ?= "P4080"
+FMAN_VARIANT_b4 = "FMAN_V3H"
+FMAN_VARIANT_t1 = "FMAN_V3L"
+FMAN_VARIANT_t2 = "FMAN_V3H"
+FMAN_VARIANT_t4 = "FMAN_V3H"
+FMAN_VARIANT_p1023rdb = "P1023"
+
+do_compile_prepend () {
+    export SOC=${SOC}
+    export FMC_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/fmc"
+    export FMLIB_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/fmd \
+        -I ${STAGING_INCDIR}/fmd/Peripherals \
+        -I ${STAGING_INCDIR}/fmd/integrations \
+        -D${FMAN_VARIANT}"
+    export USDPAA_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/usdpaa"
+    export DPAOFFLOAD_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/dpa-offload"
+    export LIBNL_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/libnl3"
+    export LIBNL_EXTRA_LDFLAGS="-lnl-3 -lnl-route-3"
+    export LIBXML2_CFLAGS="`pkg-config --cflags libxml-2.0`"
+    export LIBXML2_LDFLAGS="`pkg-config --libs --static libxml-2.0`"
+    export LIBEDIT_CFLAGS="`pkg-config --cflags libedit`"
+    export LIBEDIT_LDFLAGS="`pkg-config --libs --static libedit`"
+}
+
+do_install () {
+    export SOC=${SOC}
+    oe_runmake install DESTDIR=${D}
+}
+
+PARALLEL_MAKE_pn-${PN} = ""
+FILES_${PN} += "/root/SOURCE_THIS /usr/etc/"
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
diff --git a/recipes-dpaa/usdpaa/usdpaa_git.bb b/recipes-dpaa/usdpaa/usdpaa_git.bb
new file mode 100644
index 00000000..32cad124
--- /dev/null
+++ b/recipes-dpaa/usdpaa/usdpaa_git.bb
@@ -0,0 +1,27 @@
+DESCRIPTION = "User-Space Data-Path Acceleration Architecture Drivers"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://Makefile;endline=30;md5=39e58bedc879163c9338596e52df5b1f"
+PR = "r4"
+
+inherit pkgconfig
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS += "flib"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/usdpaa.git;nobranch=1"
+SRCREV = "3b0717952400577608a548fc4c4858a9efd1bd96"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${LD}" AR="${AR}"'
+export ARCH="${TARGET_ARCH}"
+
+do_install () {
+    oe_runmake install DESTDIR=${D}
+}
+
+PARALLEL_MAKE_pn-${PN} = ""
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"