u-boot-imx: Upgrade version 2017.03 to 2018.03

Upgrade version to 2018.03 from branch imx_v2018.03_4.14.98_2.0.0_ga.
Drop usage of dtc-145 binary, pulled by the class with the same name,
which was a workaround for older u-boot versions.

Signed-off-by: Mihai Lindner <mihai.lindner@nxp.com>

1 files changed, 48 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-imx_2018.03.bb b/recipes-bsp/u-boot/u-boot-imx_2018.03.bb
new file mode 100644
index 00000000..fcd34136
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-imx_2018.03.bb
@@ -0,0 +1,48 @@
+# Copyright (C) 2013-2016 Freescale Semiconductor
+# Copyright 2018 (C) O.S. Systems Software LTDA.
+# Copyright 2017-2019 NXP
+
+DESCRIPTION = "i.MX U-Boot suppporting i.MX reference boards."
+require recipes-bsp/u-boot/u-boot.inc
+
+PROVIDES += "u-boot"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRCBRANCH = "imx_v2018.03_4.14.98_2.0.0_ga"
+SRC_URI = "git://source.codeaurora.org/external/imx/uboot-imx.git;protocol=https;branch=${SRCBRANCH}"
+SRCREV = "0d6d8807793e74402e23772062469aeb4808dd48"
+
+S = "${WORKDIR}/git"
+
+inherit fsl-u-boot-localversion
+
+LOCALVERSION ?= "-${SRCBRANCH}"
+
+BOOT_TOOLS = "imx-boot-tools"
+
+do_deploy_append_mx8m() {
+    # Deploy the mkimage, u-boot-nodtb.bin and fsl-imx8m*-XX.dtb for mkimage to generate boot binary
+    if [ -n "${UBOOT_CONFIG}" ]
+    then
+        for config in ${UBOOT_MACHINE}; do
+            i=$(expr $i + 1);
+            for type in ${UBOOT_CONFIG}; do
+                j=$(expr $j + 1);
+                if [ $j -eq $i ]
+                then
+                    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+                    install -m 0777 ${B}/${config}/arch/arm/dts/${UBOOT_DTB_NAME}  ${DEPLOYDIR}/${BOOT_TOOLS}
+                    install -m 0777 ${B}/${config}/tools/mkimage  ${DEPLOYDIR}/${BOOT_TOOLS}/mkimage_uboot
+                    install -m 0777 ${B}/${config}/u-boot-nodtb.bin  ${DEPLOYDIR}/${BOOT_TOOLS}/u-boot-nodtb.bin
+                fi
+            done
+            unset  j
+        done
+        unset  i
+    fi
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"