u-boot-fslc: upgrade to v2024.01

U-Boot fork has been updated to include tagged version v2024.01 from
upstream.

Following commits were ported from 2023.10+fslc to this version:
- 9ff224ca003 imx: iMX6: Define disconnect_from_pc function
- a429b3dcdd5 MLK-21854-2 imx: uuu: Update autoboot to run uuu or fastboot
- cbfd9b3fd03 pico-imx6ul, pico-imx7d: Explain how to use eMMC user partition
- 58cb813aa7e mx6sabre_common: Dynamically change the video output
- f1ac9d18650 mx6sabresd: Enable video interfaces in bootargs

Signed-off-by: Oleksandr Suvorov <oleksandr.suvorov@foundries.io>

1 files changed, 42 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2024.01.bb b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2024.01.bb
new file mode 100644
index 00000000..b7e4ca76
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2024.01.bb
@@ -0,0 +1,42 @@
+require u-boot-fslc-common_${PV}.inc
+
+DESCRIPTION = "U-boot bootloader mxsboot tool"
+SECTION = "bootloader"
+
+inherit python3native
+
+DEPENDS += " \
+    bison-native \
+    dtc \
+    gnutls \
+    openssl \
+    python3-setuptools-native \
+    swig-native \
+    util-linux-libuuid \
+"
+
+PROVIDES = "u-boot-mxsboot"
+
+EXTRA_OEMAKE:class-target = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+EXTRA_OEMAKE:class-native = 'CC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+EXTRA_OEMAKE:class-nativesdk = 'CROSS_COMPILE="${HOST_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+
+do_compile () {
+    oe_runmake -C ${S} O=${B} tools-only_defconfig
+
+    # Disable CONFIG_CMD_LICENSE, license.h is not used by tools and
+    # generating it requires bin2header tool, which for target build
+    # is built with target tools and thus cannot be executed on host.
+    sed -i "s/CONFIG_CMD_LICENSE=.*/# CONFIG_CMD_LICENSE is not set/" .config
+
+    oe_runmake -C ${S} O=${B} cross_tools NO_SDL=1
+}
+
+do_install () {
+    install -Dm 0755 tools/mxsboot ${D}${bindir}/uboot-mxsboot
+    ln -sf uboot-mxsboot ${D}${bindir}/mxsboot
+}
+
+COMPATIBLE_MACHINE:class-target = "(mxs-generic-bsp)"
+
+BBCLASSEXTEND = "native nativesdk"