Move meta-fsl-arm content to layer root

The meta-fsl-arm is going to be used as the base for this layer. It
contains a clean history and allowing a more granullar set of changes.

This commit is just a rename of all contents of meta-fsl-arm
subdirectory to this layer's root, subsequent changes are based on top
of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 35 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2015.04.bb b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2015.04.bb
new file mode 100644
index 00000000..3981b604
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2015.04.bb
@@ -0,0 +1,35 @@
+DESCRIPTION = "U-boot bootloader mxsboot tool"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=c7383a594871c03da76b3707929d2919"
+SECTION = "bootloader"
+DEPENDS = "openssl"
+PROVIDES = "u-boot-mxsboot"
+
+PV = "v2015.04+git${SRCPV}"
+
+SRCREV = "10aced37cecf117e54e71bd700228f57dc34e579"
+SRCBRANCH = "patches-2015.04"
+
+SRC_URI = "git://github.com/Freescale/u-boot-fslc.git;branch=${SRCBRANCH}"
+
+S = "${WORKDIR}/git"
+
+inherit fsl-u-boot-localversion
+
+EXTRA_OEMAKE = 'HOSTCC="${CC} ${CPPFLAGS}" HOSTLDFLAGS="-L${libdir} -L${base_libdir}" HOSTSTRIP=true CONFIG_MX28=y'
+
+do_configure () {
+    oe_runmake sandbox_defconfig
+}
+
+do_compile () {
+    oe_runmake tools-only
+}
+
+do_install () {
+    install -d ${D}${bindir}
+    install -m 0755 tools/mxsboot ${D}${bindir}/uboot-mxsboot
+    ln -sf uboot-mxsboot ${D}${bindir}/mxsboot
+}
+
+BBCLASSEXTEND = "native nativesdk"