diff options
author | Otavio Salvador <otavio@ossystems.com.br> | 2022-11-25 16:56:04 -0300 |
---|---|---|
committer | GitHub <noreply@github.com> | 2022-11-25 16:56:04 -0300 |
commit | 04f1419518d41db95f3f33d1d82c1d00853715ff (patch) | |
tree | 15af260703fe7b884ee3ea7fe4b83e950a80805f /recipes-bsp/isp-imx/isp-imx_4.2.2.19.0.bb | |
parent | 916f0760aa0f6ec29b7c74bbac1806cd1d9afb75 (diff) | |
parent | d0bd76df6c13f735433f202ec107ca42529f13b0 (diff) | |
download | meta-freescale-04f1419518d41db95f3f33d1d82c1d00853715ff.tar.gz |
Merge pull request #1312 from Freescale/backport-1310-to-kirkstone
[Backport kirkstone] Upgrade Multimedia Packages to lf5.15.52_2.1.0
Diffstat (limited to 'recipes-bsp/isp-imx/isp-imx_4.2.2.19.0.bb')
-rw-r--r-- | recipes-bsp/isp-imx/isp-imx_4.2.2.19.0.bb | 89 |
1 files changed, 89 insertions, 0 deletions
diff --git a/recipes-bsp/isp-imx/isp-imx_4.2.2.19.0.bb b/recipes-bsp/isp-imx/isp-imx_4.2.2.19.0.bb new file mode 100644 index 00000000..19d0cba7 --- /dev/null +++ b/recipes-bsp/isp-imx/isp-imx_4.2.2.19.0.bb | |||
@@ -0,0 +1,89 @@ | |||
1 | # Copyright 2020-2022 NXP | ||
2 | |||
3 | DESCRIPTION = "i.MX Verisilicon Software ISP" | ||
4 | LICENSE = "Proprietary" | ||
5 | LIC_FILES_CHKSUM = "file://COPYING;md5=5a0bf11f745e68024f37b4724a5364fe" | ||
6 | DEPENDS = "libdrm virtual/libg2d libtinyxml2" | ||
7 | |||
8 | SRC_URI = "${FSL_MIRROR}/${BP}.bin;fsl-eula=true" | ||
9 | SRC_URI[md5sum] = "d0350ad40df96a84efc4802975f92c91" | ||
10 | SRC_URI[sha256sum] = "5544aef41546906bc4999de1980e4706cf241c93732633efde57b018ac4863c3" | ||
11 | |||
12 | inherit fsl-eula-unpack cmake systemd use-imx-headers | ||
13 | |||
14 | # Build the sub-folder appshell | ||
15 | OECMAKE_SOURCEPATH = "${S}/appshell" | ||
16 | |||
17 | # Use make instead of ninja | ||
18 | OECMAKE_GENERATOR = "Unix Makefiles" | ||
19 | |||
20 | # Workaround for linking issues seen with gold linker | ||
21 | LDFLAGS:append = "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', ' -fuse-ld=bfd ', '', d)}" | ||
22 | |||
23 | SYSTEMD_SERVICE:${PN} = "imx8-isp.service" | ||
24 | |||
25 | EXTRA_OECMAKE += " \ | ||
26 | -DSDKTARGETSYSROOT=${STAGING_DIR_HOST} \ | ||
27 | -DCMAKE_BUILD_TYPE=release \ | ||
28 | -DCMAKE_BUILD_WITH_INSTALL_RPATH=ON \ | ||
29 | -DISP_VERSION=ISP8000NANO_V1802 \ | ||
30 | -DPLATFORM=ARM64 \ | ||
31 | -DAPPMODE=V4L2 \ | ||
32 | -DQTLESS=1 \ | ||
33 | -DFULL_SRC_COMPILE=1 \ | ||
34 | -DWITH_DRM=1 \ | ||
35 | -DWITH_DWE=1 \ | ||
36 | -DSERVER_LESS=1 \ | ||
37 | -DSUBDEV_V4L2=1 \ | ||
38 | -DENABLE_IRQ=1 \ | ||
39 | -DPARTITION_BUILD=0 \ | ||
40 | -D3A_SRC_BUILD=0 \ | ||
41 | -DIMX_G2D=ON \ | ||
42 | -Wno-dev \ | ||
43 | " | ||
44 | |||
45 | do_install() { | ||
46 | install -d ${D}/${libdir} | ||
47 | install -d ${D}/${includedir} | ||
48 | install -d ${D}/opt/imx8-isp/bin | ||
49 | install -d ${D}/opt/imx8-isp/bin/dewarp_config | ||
50 | |||
51 | cp -r ${B}/generated/release/bin/*_test ${D}/opt/imx8-isp/bin | ||
52 | cp -r ${B}/generated/release/bin/*2775* ${D}/opt/imx8-isp/bin | ||
53 | cp -r ${B}/generated/release/bin/*.xml ${D}/opt/imx8-isp/bin | ||
54 | cp -r ${B}/generated/release/bin/*.drv ${D}/opt/imx8-isp/bin | ||
55 | cp -r ${WORKDIR}/${BP}/dewarp/dewarp_config/ ${D}/opt/imx8-isp/bin | ||
56 | cp -r ${B}/generated/release/bin/isp_media_server ${D}/opt/imx8-isp/bin | ||
57 | cp -r ${B}/generated/release/bin/vvext ${D}/opt/imx8-isp/bin | ||
58 | cp -r ${B}/generated/release/lib/*.so* ${D}/${libdir} | ||
59 | cp -r ${B}/generated/release/include/* ${D}/${includedir} | ||
60 | |||
61 | cp ${S}/imx/run.sh ${D}/opt/imx8-isp/bin | ||
62 | cp ${S}/imx/start_isp.sh ${D}/opt/imx8-isp/bin | ||
63 | |||
64 | chmod +x ${D}/opt/imx8-isp/bin/run.sh | ||
65 | chmod +x ${D}/opt/imx8-isp/bin/start_isp.sh | ||
66 | |||
67 | if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then | ||
68 | install -d ${D}${systemd_system_unitdir} | ||
69 | install -m 0644 ${S}/imx/imx8-isp.service ${D}${systemd_system_unitdir} | ||
70 | fi | ||
71 | } | ||
72 | |||
73 | # The build contains a mix of versioned and unversioned libraries, so | ||
74 | # the default packaging configuration needs some modification so that | ||
75 | # unversioned .so libraries go to the main package and versioned .so | ||
76 | # symlinks go to -dev. | ||
77 | FILES_SOLIBSDEV = "" | ||
78 | FILES_SOLIBS_VERSIONED = " \ | ||
79 | ${libdir}/libar1335.so \ | ||
80 | ${libdir}/libjsoncpp.so \ | ||
81 | ${libdir}/libos08a20.so \ | ||
82 | ${libdir}/libov2775.so \ | ||
83 | " | ||
84 | FILES:${PN} += "/opt ${libdir}/lib*${SOLIBSDEV}" | ||
85 | FILES:${PN}-dev += "${FILES_SOLIBS_VERSIONED}" | ||
86 | |||
87 | RDEPENDS:${PN} = "libdrm" | ||
88 | |||
89 | COMPATIBLE_MACHINE = "(mx8mp-nxp-bsp)" | ||