isp-imx: Upgrade to 4.2.2.13.0

a52c0446d change version number to p13
800e0f8d8 Fix M865SW-753:copy sensor init txt just for native
a4210be47 remove unused VVCAM_PARAMS
ad8728441 add dual basler camera mode 4 for 1080p25hdr
eea1908b8 cleanup the build script
da5bd492b remove vvnative which is only for local test
c725c6266 Revert "cleanup for unused config file"
a399dbd70 cleanup for unused config file
1bd986e2d Remove basler binary driver from source build
98ef8c98a New partial build partial_release_20210430_4.2.2_p12
31d26c84d Update Release P12 from Verisilicon
c82e5b9bb limit basler camera resolution to 1080p when ov5640 is also used
8c9825a6d add a trailing '/' for file search in directory
f101a6a64 Update Release form Verisilicon
fbfe4fda0 add a blank line for good readability
91663d97c enlarge the StartLimitBurst
0c3dc6a6e add explanatory to the tunning example for video_test
365e7f8f5 BSLRM865-124: improve the running example for video_test
253818b3f Segment error caused by DTS modification
a8a906d4d M865SW-703 Use reversed memory only for tuning tool
7c40835b2 Remove basler binary driver from source build
9bf7ff1ba BSLRM865-131 fix crop seems scale
aee50d3d0 imx8-isp.service: do not prevent restart of service
3232149ac run.sh: fix bashism
5fbf584d2 Removing action for copying run-imx.sh as it's gone
860346a5d Update Release form Verisilicon
f5b3c8783 MLK-25354 add user description for dual basler cameras
85ab6c183 update run script to work with P10/P11
19fb6591b update run script to same as P6
daba60f02 update Release form Verisilicon

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>

1 files changed, 86 insertions, 0 deletions

diff --git a/recipes-bsp/isp-imx/isp-imx_4.2.2.13.0.bb b/recipes-bsp/isp-imx/isp-imx_4.2.2.13.0.bb
new file mode 100644
index 00000000..ec15dfb9
--- /dev/null
+++ b/recipes-bsp/isp-imx/isp-imx_4.2.2.13.0.bb
@@ -0,0 +1,86 @@
+# Copyright 2020-2021 NXP
+
+DESCRIPTION = "i.MX Verisilicon Software ISP"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=417b82f17fc02b88125331ed312f6f1b"
+DEPENDS = "python3 libdrm virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${BP}.bin;fsl-eula=true \
+           file://0001-start_isp.sh-fix-test-to-be-generic.patch \
+"
+
+SRC_URI[md5sum] = "123feed48302fea2a1be8572e913ae47"
+SRC_URI[sha256sum] = "e775975684aab4211f0bf8c5e2c6604ba46b83c5586937000675e044a50d77b8"
+
+inherit fsl-eula-unpack cmake systemd use-imx-headers
+
+# Build the sub-folder appshell
+OECMAKE_SOURCEPATH = "${S}/appshell"
+
+# Use make instead of ninja
+OECMAKE_GENERATOR = "Unix Makefiles"
+
+SYSTEMD_SERVICE_${PN} = "imx8-isp.service"
+
+EXTRA_OECMAKE += " \
+    -DCMAKE_BUILD_TYPE=release \
+    -DISP_VERSION=ISP8000NANO_V1802 \
+    -DPLATFORM=ARM64 \
+    -DAPPMODE=V4L2 \
+    -DQTLESS=1 \
+    -DFULL_SRC_COMPILE=1 \
+    -DWITH_DRM=1 \
+    -DWITH_DWE=1 \
+    -DSERVER_LESS=1 \
+    -DSUBDEV_V4L2=1 \
+    -DENABLE_IRQ=1 \
+    -DPARTITION_BUILD=0 \
+    -D3A_SRC_BUILD=0 \
+    -DIMX_G2D=ON \
+    -Wno-dev \
+"
+
+do_configure_prepend() {
+    export SDKTARGETSYSROOT=${STAGING_DIR_HOST}
+}
+
+do_install() {
+    install -d ${D}/${libdir}
+    install -d ${D}/${includedir}
+    install -d ${D}/opt/imx8-isp/bin
+
+    cp -r ${WORKDIR}/build/generated/release/bin/*_test ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/bin/*2775* ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/bin/isp_media_server ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/bin/vvext ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/${BP}/dewarp/dewarp_config/ ${D}/opt/imx8-isp/bin
+    cp -r ${WORKDIR}/build/generated/release/lib/*.so* ${D}/${libdir}
+    cp -r ${WORKDIR}/build/generated/release/include/* ${D}/${includedir}
+
+    cp ${WORKDIR}/${BP}/imx/run.sh ${D}/opt/imx8-isp/bin
+    cp ${WORKDIR}/${BP}/imx/start_isp.sh ${D}/opt/imx8-isp/bin
+
+    chmod +x ${D}/opt/imx8-isp/bin/run.sh
+    chmod +x ${D}/opt/imx8-isp/bin/start_isp.sh
+
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+      install -d ${D}${systemd_system_unitdir}
+      install -m 0644 ${WORKDIR}/${BP}/imx/imx8-isp.service ${D}${systemd_system_unitdir}
+    fi
+}
+
+# The build contains a mix of versioned and unversioned libraries, so
+# the default packaging configuration needs some modifications
+FILES_SOLIBSDEV = ""
+FILES_${PN} += "/opt ${libdir}/lib*${SOLIBSDEV}"
+FILES_${PN}-dev += " \
+    ${libdir}/libjsoncpp.so \
+    ${libdir}/libos08a20.so \
+    ${libdir}/libov2775.so \
+"
+
+INSANE_SKIP_${PN} = "rpaths"
+
+RDEPENDS_${PN} = "libdrm libpython3"
+
+COMPATIBLE_MACHINE = "(mx8mp)"