firmware-imx-8*: Add new firmware recipes for i.MX 8 series

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>

3 files changed, 69 insertions, 0 deletions

diff --git a/recipes-bsp/firmware-imx/firmware-imx-8_7.8.bb b/recipes-bsp/firmware-imx/firmware-imx-8_7.8.bb
new file mode 100644
index 00000000..d99aa41b
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx-8_7.8.bb
@@ -0,0 +1,25 @@
+# Copyright 2018 NXP
+SUMMARY = "Freescale i.MX firmware for 8 family"
+DESCRIPTION = "Freescale i.MX firmware for 8 family"
+
+require firmware-imx-${PV}.inc
+
+inherit deploy
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    # Cadence HDMI
+    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${DEPLOYDIR}
+    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${DEPLOYDIR}
+    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${DEPLOYDIR}
+    # SECO
+    install -m 0644 ${S}/firmware/seco/mx8qm-ahab-container.img ${DEPLOYDIR}
+}
+addtask deploy after do_install before do_build
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE      = "(mx8)"
+COMPATIBLE_MACHINE_mx8m = "(^$)"
+COMPATIBLE_MACHINE_mx8x = "(^$)"
diff --git a/recipes-bsp/firmware-imx/firmware-imx-8m_7.8.bb b/recipes-bsp/firmware-imx/firmware-imx-8m_7.8.bb
new file mode 100644
index 00000000..a605d226
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx-8m_7.8.bb
@@ -0,0 +1,24 @@
+# Copyright 2018 NXP
+SUMMARY = "Freescale i.MX firmware for 8M and 8M Mini family"
+DESCRIPTION = "Freescale i.MX firmware for 8M and 8M Mini family"
+
+require firmware-imx-${PV}.inc
+
+inherit deploy
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    # Synopsys DDR
+    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
+        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
+    done
+    # Cadence DP and HDMI
+    install -m 0644 ${S}/firmware/hdmi/cadence/signed_dp_imx8m.bin ${DEPLOYDIR}
+    install -m 0644 ${S}/firmware/hdmi/cadence/signed_hdmi_imx8m.bin ${DEPLOYDIR}
+}
+addtask deploy after do_install before do_build
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE = "(mx8m)"
diff --git a/recipes-bsp/firmware-imx/firmware-imx-8x_7.8.bb b/recipes-bsp/firmware-imx/firmware-imx-8x_7.8.bb
new file mode 100644
index 00000000..85d394a0
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx-8x_7.8.bb
@@ -0,0 +1,20 @@
+# Copyright 2018 NXP
+SUMMARY = "Freescale i.MX firmware for 8X family"
+DESCRIPTION = "Freescale i.MX firmware for 8X family"
+
+require firmware-imx-${PV}.inc
+
+inherit deploy
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    # SECO
+    install -m 0644 ${S}/firmware/seco/mx8qx-ahab-container.img ${DEPLOYDIR}
+}
+
+addtask deploy after do_install before do_build
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE = "(mx8x)"