Move meta-fsl-arm content to layer root

The meta-fsl-arm is going to be used as the base for this layer. It
contains a clean history and allowing a more granullar set of changes.

This commit is just a rename of all contents of meta-fsl-arm
subdirectory to this layer's root, subsequent changes are based on top
of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

2 files changed, 50 insertions, 0 deletions

diff --git a/recipes-bsp/firmware-imx/firmware-imx.inc b/recipes-bsp/firmware-imx/firmware-imx.inc
new file mode 100644
index 00000000..80e5e59e
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx.inc
@@ -0,0 +1,42 @@
+SUMMARY = "Freescale IMX firmware"
+DESCRIPTION = "Freescale IMX firmware such as for the VPU"
+SECTION = "base"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=acdb807ac7275fe32f9f64992e111241"
+
+PE = "1"
+
+SRC_URI = "${FSL_MIRROR}/firmware-imx-${PV}.bin;fsl-eula=true"
+
+inherit fsl-eula-unpack
+
+do_install() {
+    install -d ${D}/lib/firmware
+    cp -rfv firmware/* ${D}/lib/firmware/
+    find ${D}/lib/firmware -type f -exec chmod 644 '{}' ';'
+
+    # Remove files not going to be installed
+    find ${D}/lib/firmware/ -name Android.mk -exec rm '{}' ';'
+}
+
+python populate_packages_prepend() {
+    vpudir = bb.data.expand('/lib/firmware/vpu', d)
+    do_split_packages(d, vpudir, '^vpu_fw_([^_]*).*\.bin',
+                      output_pattern='firmware-imx-vpu-%s',
+                      description='Freescale IMX Firmware %s',
+                      extra_depends='',
+                      prepend=True)
+
+    sdmadir = bb.data.expand('/lib/firmware/sdma', d)
+    do_split_packages(d, sdmadir, '^sdma-([^-]*).*\.bin',
+                      output_pattern='firmware-imx-sdma-%s',
+                      description='Freescale IMX Firmware %s',
+                      extra_depends='',
+                      prepend=True)
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGES_DYNAMIC = "${PN}-vpu-* ${PN}-sdma-*"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
diff --git a/recipes-bsp/firmware-imx/firmware-imx_3.14.28-1.0.0.bb b/recipes-bsp/firmware-imx/firmware-imx_3.14.28-1.0.0.bb
new file mode 100644
index 00000000..408baf18
--- /dev/null
+++ b/recipes-bsp/firmware-imx/firmware-imx_3.14.28-1.0.0.bb
@@ -0,0 +1,8 @@
+# Copyright (C) 2012-2015 Freescale Semiconductor
+
+require firmware-imx.inc
+
+SRC_URI[md5sum] = "6e700f3d3a6482db08d5aabee7751630"
+SRC_URI[sha256sum] = "1f09acd4d605efc78a0672068a658cb16274811d2f444cf3ae7aaa075266746f"
+
+COMPATIBLE_MACHINE = "(mx5|mx6)"