imx-boot-firmware-files: consolidate deploy firmware files across SoCsrework-firmware-imx

The firmware-imx-8 and firmware-imx-8m recipes are mostly code
duplication and some parts even used by i.MX93 so consolidating it
allows code reuse and clearness.

Fixes: #1426.
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 62 insertions, 0 deletions

diff --git a/recipes-bsp/firmware-imx/imx-boot-firmware-files_8.18.bb b/recipes-bsp/firmware-imx/imx-boot-firmware-files_8.18.bb
new file mode 100644
index 00000000..d4408cf1
--- /dev/null
+++ b/recipes-bsp/firmware-imx/imx-boot-firmware-files_8.18.bb
@@ -0,0 +1,62 @@
+# Copyright (C) 2018-2020 NXP
+SUMMARY = "Freescale i.MX firmware for 8 family"
+DESCRIPTION = "Freescale i.MX firmware for 8 family"
+
+require firmware-imx-${PV}.inc
+
+inherit deploy nopackages
+
+do_install[noexec] = "1"
+
+DEPLOY_FOR                  = ""
+DEPLOY_FOR:mx8-generic-bsp  = "mx8"
+DEPLOY_FOR:mx8m-generic-bsp = "mx8 mx8m"
+DEPLOY_FOR:mx9-generic-bsp  = "mx9"
+
+deploy_for_mx8() {
+    # Cadence HDMI
+    install -m 0644 ${S}/firmware/hdmi/cadence/hdmitxfw.bin ${DEPLOYDIR}
+    install -m 0644 ${S}/firmware/hdmi/cadence/hdmirxfw.bin ${DEPLOYDIR}
+    install -m 0644 ${S}/firmware/hdmi/cadence/dpfw.bin ${DEPLOYDIR}
+}
+
+deploy_for_mx8m() {
+    # Synopsys DDR
+    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
+        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
+    done
+
+    # Cadence DP and HDMI
+    install -m 0644 ${S}/firmware/hdmi/cadence/signed_dp_imx8m.bin ${DEPLOYDIR}
+    install -m 0644 ${S}/firmware/hdmi/cadence/signed_hdmi_imx8m.bin ${DEPLOYDIR}
+}
+
+
+deploy_for_mx9() {
+    # Synopsys DDR
+    for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
+        install -m 0644 ${S}/firmware/ddr/synopsys/${ddr_firmware} ${DEPLOYDIR}
+    done
+}
+
+python () {
+    # Manually add the required functions as dependencies otherwise they won't be included in the
+    # final run script.
+    deploy_for = d.getVar('DEPLOY_FOR', True).split()
+    for soc in deploy_for:
+        d.appendVarFlag('do_deploy', 'vardeps', ' deploy_for_%s' % soc)
+}
+
+do_deploy () {
+    for soc in ${DEPLOY_FOR}; do
+        bbnote "Running deploy for $soc"
+        deploy_for_$soc
+    done
+}
+
+addtask deploy after do_install before do_build
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE                  = "(mx8-generic-bsp|mx9-generic-bsp)"
+COMPATIBLE_MACHINE:mx8x-generic-bsp = "(^$)"