diff options
author | Cristinel Panfir <cristinel.panfir@nxp.com> | 2019-12-11 11:54:09 +0200 |
---|---|---|
committer | Otavio Salvador <otavio@ossystems.com.br> | 2019-12-16 11:36:29 -0300 |
commit | 9d5f40a8506a24ddf9e873331b30c41519e6f7b0 (patch) | |
tree | e702cf957ddb531d517d7ed1775bf06c98f76bb6 /recipes-bsp/firmware-imx/firmware-imx_8.5.bb | |
parent | 67f797dafa14873a07fb5b28d2e0bb8b68ff585a (diff) | |
download | meta-freescale-9d5f40a8506a24ddf9e873331b30c41519e6f7b0.tar.gz |
firmware-imx: Upgrade to version 8.5
- Exclude "easrc" as this IP is only applicable for Nano Soc
- Remove SECO implementation from firmware-imx recipe and use imx-seco
to deploy the SECO firmware for i.MX 8QM/8QXP
Signed-off-by: Cristinel Panfir <cristinel.panfir@nxp.com>
Diffstat (limited to 'recipes-bsp/firmware-imx/firmware-imx_8.5.bb')
-rw-r--r-- | recipes-bsp/firmware-imx/firmware-imx_8.5.bb | 78 |
1 files changed, 78 insertions, 0 deletions
diff --git a/recipes-bsp/firmware-imx/firmware-imx_8.5.bb b/recipes-bsp/firmware-imx/firmware-imx_8.5.bb new file mode 100644 index 00000000..549a86e6 --- /dev/null +++ b/recipes-bsp/firmware-imx/firmware-imx_8.5.bb | |||
@@ -0,0 +1,78 @@ | |||
1 | # Copyright (C) 2012-2016 Freescale Semiconductor | ||
2 | # Copyright 2017-2019 NXP | ||
3 | # Copyright (C) 2018 O.S. Systems Software LTDA. | ||
4 | SUMMARY = "Freescale i.MX firmware" | ||
5 | DESCRIPTION = "Freescale i.MX firmware such as for the VPU" | ||
6 | |||
7 | require firmware-imx-${PV}.inc | ||
8 | |||
9 | PE = "1" | ||
10 | |||
11 | SRC_URI += " \ | ||
12 | git://github.com/NXP/imx-firmware.git;protocol=https;branch=${SRCBRANCH};destsuffix=${S}/git \ | ||
13 | " | ||
14 | SRCREV = "8ce9046f5058fdd2c5271f86ccfc61bc5a248ae3" | ||
15 | |||
16 | inherit allarch | ||
17 | |||
18 | do_install() { | ||
19 | install -d ${D}${base_libdir}/firmware/imx | ||
20 | |||
21 | cd firmware | ||
22 | for d in *; do | ||
23 | case $d in | ||
24 | easrc) | ||
25 | # excluding as only applies Nano SoC | ||
26 | ;; | ||
27 | ddr|hdmi|seco) | ||
28 | # These folders are for i.MX 8 and are included in the boot image via imx-boot | ||
29 | bbnote Excluding folder $d | ||
30 | ;; | ||
31 | *) | ||
32 | cp -rfv $d ${D}${base_libdir}/firmware | ||
33 | ;; | ||
34 | esac | ||
35 | done | ||
36 | cd - | ||
37 | |||
38 | install -d ${D}${base_libdir}/firmware/imx/sdma | ||
39 | mv ${D}${base_libdir}/firmware/sdma/sdma-imx6q.bin ${D}${base_libdir}/firmware/imx/sdma | ||
40 | mv ${D}${base_libdir}/firmware/sdma/sdma-imx7d.bin ${D}${base_libdir}/firmware/imx/sdma | ||
41 | |||
42 | mv ${D}${base_libdir}/firmware/epdc/ ${D}${base_libdir}/firmware/imx/epdc/ | ||
43 | mv ${D}${base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw.nonrestricted ${D}${base_libdir}/firmware/imx/epdc/epdc_ED060XH2C1.fw | ||
44 | |||
45 | find ${D}${base_libdir}/firmware -type f -exec chmod 644 '{}' ';' | ||
46 | find ${D}${base_libdir}/firmware -type f -exec chown root:root '{}' ';' | ||
47 | |||
48 | # Remove files not going to be installed | ||
49 | find ${D}${base_libdir}/firmware/ -name '*.mk' -exec rm '{}' ';' | ||
50 | } | ||
51 | |||
52 | python populate_packages_prepend() { | ||
53 | vpudir = bb.data.expand('${base_libdir}/firmware/vpu', d) | ||
54 | do_split_packages(d, vpudir, '^vpu_fw_([^_]*).*\.bin', | ||
55 | output_pattern='firmware-imx-vpu-%s', | ||
56 | description='Freescale IMX Firmware %s', | ||
57 | extra_depends='', | ||
58 | prepend=True) | ||
59 | |||
60 | sdmadir = bb.data.expand('${base_libdir}/firmware/sdma', d) | ||
61 | do_split_packages(d, sdmadir, '^sdma-([^-]*).*\.bin', | ||
62 | output_pattern='firmware-imx-sdma-%s', | ||
63 | description='Freescale IMX Firmware %s', | ||
64 | extra_depends='', | ||
65 | prepend=True) | ||
66 | } | ||
67 | |||
68 | ALLOW_EMPTY_${PN} = "1" | ||
69 | |||
70 | PACKAGES_DYNAMIC = "${PN}-vpu-* ${PN}-sdma-*" | ||
71 | |||
72 | PACKAGES =+ "${PN}-epdc ${PN}-scfw ${PN}-sdma" | ||
73 | |||
74 | FILES_${PN}-epdc = "${base_libdir}/firmware/imx/epdc/" | ||
75 | FILES_${PN}-scfw = "${base_libdir}/firmware/scfw/" | ||
76 | FILES_${PN}-sdma = " ${base_libdir}/firmware/imx/sdma" | ||
77 | |||
78 | COMPATIBLE_MACHINE = "(imx)" | ||