imx8dxl-evk: Add new board i.MX DXL EVK

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>

2 files changed, 59 insertions, 0 deletions

diff --git a/conf/machine/imx8dxl-evk.conf b/conf/machine/imx8dxl-evk.conf
new file mode 100644
index 00000000..c0427314
--- /dev/null
+++ b/conf/machine/imx8dxl-evk.conf
@@ -0,0 +1,56 @@
+#@TYPE: Machine
+#@NAME: i.MX 8DXL EVK
+#@DESCRIPTION: i.MX 8DXLite Evaluation Kit (EVK) board
+#@MAINTAINER: Lauren Post <lauren.post@nxp.com>
+
+MACHINEOVERRIDES =. "mx8:mx8x:mx8dxl:"
+
+require conf/machine/include/imx-base.inc
+require conf/machine/include/tune-cortexa35.inc
+
+MACHINE_FEATURES += "pci bcm43455 bcm4356"
+MACHINE_FEATURES_append_use-nxp-bsp = " bcm4359"
+
+# Don't include kernels in standard images
+RDEPENDS_${KERNEL_PACKAGE_NAME}-base = ""
+
+LOADADDR = ""
+
+# Disable the serial console due to auto-serial-console
+SERIAL_CONSOLES = "115200;ttyLP0"
+
+# we do not want to have getty running on tty1 as we run
+# auto-serial-console there
+USE_VT = "0"
+
+KERNEL_DEVICETREE = "freescale/imx8dxl-evk.dtb"
+KERNEL_DEVICETREE_append_use-nxp-bsp = " \
+    freescale/imx8dxl-evk-enet0.dtb \
+    freescale/imx8dxl-evk-enet0-tja1100.dtb \
+    freescale/imx8dxl-evk-inmate.dtb \
+    freescale/imx8dxl-evk-lpspi-slave.dtb \
+    freescale/imx8dxl-evk-pcie-ep.dtb \
+    freescale/imx8dxl-evk-root.dtb \
+    freescale/imx8dxl-evk-rpmsg.dtb \
+"
+
+UBOOT_MAKE_TARGET = "all"
+SPL_BINARY = "spl/u-boot-spl.bin"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd]   = "imx8dxl_evk_defconfig,sdcard"
+UBOOT_CONFIG[fspi] = "imx8dxl_evk_fspi_defconfig"
+
+IMX_BOOT_SEEK = "32"
+
+IMXBOOT_TARGETS_SD = \
+    "${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'flash_spl', \
+                                                       'flash', d)}"
+IMXBOOT_TARGETS_FSPI = \
+    "${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'flash_spl_flexspi', \
+                                                       'flash_flexspi', d)}"
+IMXBOOT_TARGETS = \
+    "${@bb.utils.contains('UBOOT_CONFIG',        'sd', '${IMXBOOT_TARGETS_SD}', \
+                                                       '${IMXBOOT_TARGETS_FSPI}', d)}"
+
+BOARD_TYPE = "evk"
diff --git a/conf/machine/include/imx-base.inc b/conf/machine/include/imx-base.inc
index 23175318..6314a20e 100644
--- a/conf/machine/include/imx-base.inc
+++ b/conf/machine/include/imx-base.inc
@@ -106,6 +106,7 @@ MACHINEOVERRIDES_EXTENDER_mx8mn  = "imxdrm:imxgpu:imxgpu3d"
 MACHINEOVERRIDES_EXTENDER_mx8mp  = "imxdrm:imxvpu:imxgpu:imxgpu2d:imxgpu3d"
 MACHINEOVERRIDES_EXTENDER_mx8mq  = "imxdrm:imxvpu:imxgpu:imxgpu3d"
 MACHINEOVERRIDES_EXTENDER_mx8qxp = "imxdrm:imxdpu:imxgpu:imxgpu2d:imxgpu3d"
+MACHINEOVERRIDES_EXTENDER_mx8dxl = "imxfbdev"
 
 MACHINEOVERRIDES_EXTENDER_FILTER_OUT_use-mainline-bsp = " \
     imx \
@@ -132,6 +133,7 @@ MACHINEOVERRIDES_EXTENDER_FILTER_OUT_use-mainline-bsp = " \
     mx8mp \
     mx8mq \
     mx8qxp \
+    mx8dxl \
 "
 
 # Sub-architecture support
@@ -154,6 +156,7 @@ MACHINE_SOCARCH_SUFFIX_mx8mn  = "-mx8mn"
 MACHINE_SOCARCH_SUFFIX_mx8mp  = "-mx8mp"
 MACHINE_SOCARCH_SUFFIX_mx8mq  = "-mx8m"
 MACHINE_SOCARCH_SUFFIX_mx8qxp = "-mx8"
+MACHINE_SOCARCH_SUFFIX_mx8dxl = "-mx8dxl"
 MACHINE_SOCARCH_SUFFIX_use-mainline-bsp = "-imx"
 
 MACHINE_ARCH_FILTER = "virtual/kernel"