From c158582c0fc7f4bd73980fe9adad446855f4d61b Mon Sep 17 00:00:00 2001
From: Tudor Florea <tudor.florea@enea.com>
Date: Fri, 10 Oct 2014 03:19:54 +0200
Subject: initial commit for Enea Linux 4.0-140929

Migrated from the internal git server on the daisy-enea-point-release branch

Signed-off-by: Tudor Florea <tudor.florea@enea.com>
---
 recipes-test/udt/udt_git.bb | 46 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 recipes-test/udt/udt_git.bb

(limited to 'recipes-test/udt/udt_git.bb')

diff --git a/recipes-test/udt/udt_git.bb b/recipes-test/udt/udt_git.bb
new file mode 100644
index 0000000..a2fa358
--- /dev/null
+++ b/recipes-test/udt/udt_git.bb
@@ -0,0 +1,46 @@
+SUMMARY = "UDP-based Data Transfer"
+DESCRIPTION = "UDT is a reliable UDP based application level data transport protocol for distributed data intensive applications over wide area high-speed networks."
+HOMEPAGE = "http://udt.sourceforge.net/"
+SECTION = "net/utils"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=567e8c8da655afbe9ad8ec73696cc31e"
+
+SRCREV = "6b4216d8a4c9b8e1e9413ad6cf473f71e7b80502"
+SRC_URI = "git://git.code.sf.net/p/udt/git \
+    file://0001-Makefile-use-g-from-environment-if-available.patch;striplevel=2 \
+    file://0002-Makefile-Add-support-for-building-on-powerpc64.patch;striplevel=2 \
+    file://0003-Makefile-Add-support-for-building-on-ARM7.patch;striplevel=2 \
+    "
+
+S = "${WORKDIR}/git/udt4"
+B = "${S}"
+
+FILES_${PN} = "${bindir}/sendfile ${bindir}/recvfile ${libdir}/libudt.so"
+FILES_${PN}-dbg = "${bindir}/.debug/* ${libdir}/.debug/*"
+FILES_${PN}-dev = ""
+
+# UDT has a non-standard way of representing architectures
+def get_udt_arch(bb, d):
+    target_arch = bb.data.getVar('TARGET_ARCH', d, 1)
+    arch_map = {
+        'i386':    'IA32',
+        'x86_64':  'AMD64',
+        'powerpc': 'POWERPC',
+        'powerpc64': 'POWERPC64',
+        'ia64':    'IA64',
+        'arm':    'ARM7',
+    }
+    # Let non-existant arches trigger a KeyError
+    return arch_map[target_arch]
+
+do_compile() {
+  make -C ${S} os=LINUX arch=${@get_udt_arch(bb, d)}
+}
+
+do_install() {
+  install -m 0755 -d ${D}/${bindir}
+  install -m 0755 ${S}/app/sendfile ${D}/${bindir}
+  install -m 0755 ${S}/app/recvfile ${D}/${bindir}
+  install -m 0755 -d ${D}/${libdir}
+  install -m 0755 ${S}/src/libudt.so ${D}/${libdir}
+}
-- 
cgit v1.2.3-54-g00ecf