From 1b6242fc583a6b871304fb995af6dc211b58f69b Mon Sep 17 00:00:00 2001
From: Adrian Dudau <adrian.dudau@enea.com>
Date: Thu, 26 Jun 2014 13:48:23 +0200
Subject: initial commit for Enea Linux 4.0

Migrated from the internal git server on the daisy-enea branch

Signed-off-by: Adrian Dudau <adrian.dudau@enea.com>
---
 recipes-core/numad/numad_0.6.bb | 51 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 recipes-core/numad/numad_0.6.bb

(limited to 'recipes-core/numad/numad_0.6.bb')

diff --git a/recipes-core/numad/numad_0.6.bb b/recipes-core/numad/numad_0.6.bb
new file mode 100644
index 0000000..a6e8ad6
--- /dev/null
+++ b/recipes-core/numad/numad_0.6.bb
@@ -0,0 +1,51 @@
+SUMMARY = "NUMA load distributing daemon"
+DESCRIPTION = 'A user-level daemon that monitors NUMA topology and processes resource \
+consumption to facilitate good NUMA resource access of applications/virtual machines \
+to improve performance and minimize cost of remote memory latencies.'
+HOMEPAGE = "https://git.fedorahosted.org/git/numad.git"
+SECTION = "console/utils"
+
+LICENSE = "LGPLv2.1"
+
+LIC_FILES_CHKSUM = "file://numad.c;beginline=1;endline=19;md5=fc770296e974bef07ddd7033725c8e29"
+
+SRC_URI = "git://git.fedorahosted.org/git/numad.git;protocol=https;branch=master \
+           file://Makefile.patch \
+           file://test.patch \
+           file://run-ptest \
+           file://numad.init.patch \
+           file://numad.conf.patch"
+
+SRCREV = "b621838bf9c8203e87137eca28e19bcc381cde2a"
+
+S = "${WORKDIR}/git"
+
+#clear .LIBPATTERNS instead of using VPATH="${STAGING_LIBDIR}:${STAGING_DIR_HOST}/${base_libdir}"
+EXTRA_OEMAKE = 'prefix=${D}/usr TEST_DESTDIR=${D}${PTEST_PATH} .LIBPATTERNS=""'
+
+do_install () {
+        oe_runmake install
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${S}/numad.init ${D}${sysconfdir}/init.d
+        install -m 0644 ${S}/numad.conf ${D}${sysconfdir}
+}
+
+inherit update-rc.d ptest
+
+DEPENDS_${PN}-ptest += "numactl"
+RDEPENDS_${PN}-ptest += "libnuma"
+
+INITSCRIPT_NAME = "numad.init"
+#INITSCRIPT_PARAMS = "start 99 5 2 . stop 20 0 1 6 ."
+INITSCRIPT_PARAMS = "stop 20 5 2 . stop 20 0 1 6 ."
+
+#wait for numa.h
+do_compile_ptest_base[depends] += "numactl:do_populate_sysroot"
+
+do_install_ptest () {
+        oe_runmake test-install
+}
+
+do_compile_ptest () {
+        oe_runmake test
+}
-- 
cgit v1.2.3-54-g00ecf