require recipes-kernel/linux/linux-qoriq-common.inc

do_configure_prepend() {
    # copy desired defconfig so we pick it up for the real kernel_do_configure
    cp ${KERNEL_DEFCONFIG} ${B}/.config

    # add config fragments
    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
        if [ -f "${WORKDIR}/${deltacfg}" ]; then
            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
        elif [ -f "${S}/arch/powerpc/configs/${deltacfg}" ]; then
            ${S}/scripts/kconfig/merge_config.sh -m .config \
            ${S}/arch/powerpc/configs/${deltacfg}
        fi
    done

    #add git revision to the local version
    if [ "${SCMVERSION}" = "y" ]; then
            # append sdk version if SDK_VERSION is defined
            sdkversion=''
            if [ -n "${SDK_VERSION}" ]; then
                sdkversion="-${SDK_VERSION}"
            fi
            head=`git --git-dir=${S}/.git rev-parse --verify --short HEAD 2> /dev/null`
            printf "%s%s%s" $sdkversion +g $head > ${B}/.scmversion
    fi
}