From ad2bb07b6cd98da169118850671a22e60481bb44 Mon Sep 17 00:00:00 2001
From: Adrian Calianu <adrian.calianu@enea.com>
Date: Tue, 13 Mar 2018 09:37:50 +0100
Subject: grub: upgraded grub version

recipes are backported from master branch and updated to
build for aarch64 and generate startup.nsh.
It is required to generate single VNF image for qemuarm64.

Signed-off-by: Adrian Calianu <adrian.calianu@enea.com>
Signed-off-by: Martin Borg <martin.borg@enea.com>
---
 recipes-bsp/grub/grub-efi_2.02.bb | 90 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 recipes-bsp/grub/grub-efi_2.02.bb

(limited to 'recipes-bsp/grub/grub-efi_2.02.bb')

diff --git a/recipes-bsp/grub/grub-efi_2.02.bb b/recipes-bsp/grub/grub-efi_2.02.bb
new file mode 100644
index 0000000..13ee220
--- /dev/null
+++ b/recipes-bsp/grub/grub-efi_2.02.bb
@@ -0,0 +1,90 @@
+require grub2.inc
+
+GRUBPLATFORM = "efi"
+
+DEPENDS_append_class-target = " grub-efi-native"
+RDEPENDS_${PN}_class-target = "diffutils freetype"
+
+SRC_URI += " \
+           file://cfg \
+          "
+
+S = "${WORKDIR}/grub-${PV}"
+
+# Determine the target arch for the grub modules
+python __anonymous () {
+    import re
+    target = d.getVar('TARGET_ARCH')
+    if target == "x86_64":
+        grubtarget = 'x86_64'
+        grubimage = "grub-efi-bootx64.efi"
+    elif re.match('i.86', target):
+        grubtarget = 'i386'
+        grubimage = "grub-efi-bootia32.efi"
+    elif re.match('aarch64', target):
+        grubtarget = 'arm64'
+        grubimage = "grub-efi-bootaa64.efi"
+    else:
+        raise bb.parse.SkipPackage("grub-efi is incompatible with target %s" % target)
+    d.setVar("GRUB_TARGET", grubtarget)
+    d.setVar("GRUB_IMAGE", grubimage)
+}
+
+inherit deploy
+
+CACHED_CONFIGUREVARS += "ac_cv_path_HELP2MAN="
+EXTRA_OECONF += "--enable-efiemu=no"
+
+# ldm.c:114:7: error: trampoline generated for nested function 'hook' [-Werror=trampolines]
+# and many other places in the grub code when compiled with some native gcc compilers (specifically, gentoo)
+CFLAGS_append_class-native = " -Wno-error=trampolines"
+
+do_install_class-native() {
+	install -d ${D}${bindir}
+	install -m 755 grub-mkimage ${D}${bindir}
+}
+
+do_install_append_class-target() {
+    # Remove build host references...
+    find "${D}" -name modinfo.sh -type f -exec \
+        sed -i \
+        -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
+        -e 's|${DEBUG_PREFIX_MAP}||g' \
+        -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
+        {} +
+}
+
+GRUB_BUILDIN ?= "boot linux ext2 fat serial part_msdos part_gpt normal \
+                 efi_gop iso9660 search loadenv test"
+
+
+do_deploy() {
+	# Search for the grub.cfg on the local boot media by using the
+	# built in cfg file provided via this recipe
+	grub-mkimage -c ../cfg -p /EFI/BOOT -d ./grub-core/ \
+	               -O ${GRUB_TARGET}-efi -o ./${GRUB_IMAGE} \
+	               ${GRUB_BUILDIN}
+	install -m 644 ${B}/${GRUB_IMAGE} ${DEPLOYDIR}
+
+    # generate startup.nsh used by EFI to autoload grub
+    grubname=`echo ${GRUB_IMAGE} | sed -e "s/^grub-efi-//"`
+    printf 'FS0:\EFI\BOOT\%s\n' "$grubname" > ${DEPLOYDIR}/startup.nsh
+}
+
+do_deploy_class-native() {
+	:
+}
+
+addtask deploy after do_install before do_build
+
+FILES_${PN} += "${libdir}/grub/${GRUB_TARGET}-efi \
+                ${datadir}/grub \
+                "
+
+# 64-bit binaries are expected for the bootloader with an x32 userland
+INSANE_SKIP_${PN}_append_linux-gnux32 = " arch"
+INSANE_SKIP_${PN}-dbg_append_linux-gnux32 = " arch"
+INSANE_SKIP_${PN}_append_linux-muslx32 = " arch"
+INSANE_SKIP_${PN}-dbg_append_linux-muslx32 = " arch"
+
+BBCLASSEXTEND = "native"
-- 
cgit v1.2.3-54-g00ecf