1 files changed, 68 insertions, 0 deletions

diff --git a/recipes-extended/dpdk/dpdk_23.11.bb b/recipes-extended/dpdk/dpdk_23.11.bb
new file mode 100644
index 0000000..5f0f9ec
--- /dev/null
+++ b/recipes-extended/dpdk/dpdk_23.11.bb
@@ -0,0 +1,68 @@
+include dpdk.inc
+
+SRC_URI += " file://0001-config-meson-get-cpu_instruction_set-from-meson-opti.patch "
+
+STABLE = "-stable"
+BRANCH = "23.11"
+SRCREV = "eeb0605f118dae66e80faa44f7b3e88748032353"
+S = "${WORKDIR}/git"
+
+def get_cpu_instruction_set(bb, d):
+    import re
+    march = re.search(r'-march=([^\s]*)', d.getVar('CC')).group(1)
+    return march
+
+EXTRA_OEMESON = " -Dexamples=all -Dcpu_instruction_set=${@get_cpu_instruction_set(bb, d)} "
+
+COMPATIBLE_MACHINE = "null"
+COMPATIBLE_HOST:libc-musl:class-target = "null"
+COMPATIBLE_HOST:linux-gnux32 = "null"
+
+PACKAGECONFIG ??= " "
+PACKAGECONFIG[afxdp] = ",,libbpf xdp-tools"
+PACKAGECONFIG[libvirt] = ",,libvirt"
+
+RDEPENDS:${PN} += "pciutils python3-core"
+RDEPENDS:${PN}-examples += "bash"
+DEPENDS = "numactl python3-pyelftools-native"
+
+inherit meson pkgconfig
+
+INSTALL_PATH = "${prefix}/share/dpdk"
+
+do_install:append(){
+    # remove  source files
+    rm -rf ${D}/${INSTALL_PATH}/examples/*
+
+    # Install examples
+    install -m 0755 -d ${D}/${INSTALL_PATH}/examples/
+    for dirname in ${B}/examples/dpdk-*
+    do
+        if [ ! -d ${dirname} ] && [ -x ${dirname} ]; then
+            install -m 0755 ${dirname} ${D}/${INSTALL_PATH}/examples/
+        fi
+    done
+
+}
+
+PACKAGES =+ "${PN}-examples ${PN}-tools"
+
+FILES:${PN} += " ${bindir}/dpdk-testpmd \
+                 ${bindir}/dpdk-proc-info \
+                 ${libdir}/*.so* \
+                 ${libdir}/dpdk/pmds-22.0/*.so* \
+                 "
+FILES:${PN}-examples = " \
+        ${prefix}/share/dpdk/examples/* \
+        "
+
+FILES:${PN}-tools = " \
+    ${bindir}/dpdk-pdump \
+    ${bindir}/dpdk-test \
+    ${bindir}/dpdk-test-* \
+    ${bindir}/dpdk-*.py \
+    "
+
+CVE_PRODUCT = "data_plane_development_kit"
+
+INSANE_SKIP:${PN} = "dev-so"