From 2b65792bd90beaadc6d4eadc4080751c91e77a61 Mon Sep 17 00:00:00 2001
From: Bruce Ashfield <bruce.ashfield@windriver.com>
Date: Thu, 27 Mar 2014 23:49:25 -0400
Subject: rabbitmq: update to 3.2.4

The existing version of rabbitmq is showing its age, updating it to 3.2.4
so we can take advantage of better debug and new functionality.

Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com>
---
 .../rabbitmq/rabbitmq-server_3.2.4.bb              | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 meta-openstack/recipes-extended/rabbitmq/rabbitmq-server_3.2.4.bb

(limited to 'meta-openstack/recipes-extended/rabbitmq/rabbitmq-server_3.2.4.bb')

diff --git a/meta-openstack/recipes-extended/rabbitmq/rabbitmq-server_3.2.4.bb b/meta-openstack/recipes-extended/rabbitmq/rabbitmq-server_3.2.4.bb
new file mode 100644
index 0000000..87c155f
--- /dev/null
+++ b/meta-openstack/recipes-extended/rabbitmq/rabbitmq-server_3.2.4.bb
@@ -0,0 +1,60 @@
+DESCRIPTION = "High-performance AMQP-compliant message broker written in Erlang."
+HOMEPAGE = "http://www.rabbitmq.com/"
+LICENSE = "MPL-1.1"
+LIC_FILES_CHKSUM = "file://LICENSE-MPL-RabbitMQ;md5=b651d0a6feaaf2bf5eb9d36b2495c510"
+SECTION = "network"
+DEPENDS = "erlang-native libxslt python-simplejson zip-native unzip-native libxslt-native"
+PR = "r0"
+
+SRC_URI = "http://www.rabbitmq.com/releases/rabbitmq-server/v${PV}/${PN}-${PV}.tar.gz \
+           file://rabbitmq-server \
+           file://remove-docs.patch \
+           "
+
+SRC_URI[md5sum] = "09d1af64c005bc680d6790b90655d021"
+SRC_URI[sha256sum] = "a930f92b362df2f292ec5f0281aa2011eb0c668faf6e24c4653a9fc53ec43b9f"
+
+RDEPENDS_${PN} = "erlang"
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+    RABBIT_LIB_DIR=${D}${libdir}/rabbitmq/lib/${PN}-${PV}
+    DOC_INSTALL_DIR="${D}${docdir}"
+
+    sed -e "s:^RABBITMQ_HOME=.*:RABBITMQ_HOME=\"${libdir}/rabbitmq/lib/${PN}-${PV}\":g" \
+               -i ${S}/scripts/rabbitmq-env
+    oe_runmake TARGET_DIR=${D} \
+               SBIN_DIR=${D}/${bindir} \
+               MAN_DIR=${D}/${mandir} \
+               DOC_INSTALL_DIR=${DOC_INSTALL_DIR} install \
+
+    install -d ${D}${libdir}/rabbitmq/lib/${PN}-${PV}
+
+    install -d ${D}${localstatedir}/log/${PN}
+
+    install -d ${D}${sysconfdir}/init.d
+    install -m 0755 ${WORKDIR}/rabbitmq-server ${D}${sysconfdir}/init.d/rabbitmq-server
+
+    mv ${D}/ebin ${RABBIT_LIB_DIR}/ebin
+    mv ${D}/include ${RABBIT_LIB_DIR}/include
+    mv ${D}/plugins ${RABBIT_LIB_DIR}/plugins
+}
+
+inherit useradd update-rc.d
+
+USERADD_PACKAGES = "${PN}"
+GROUPADD_PARAM_${PN} = "--system rabbitmq"
+USERADD_PARAM_${PN}  = "--system --create-home --home /var/lib/rabbitmq \
+			-g rabbitmq rabbitmq"
+
+INITSCRIPT_NAME = "rabbitmq-server"
+INITSCRIPT_PARAMS = "defaults"
+
+FILES_${PN} += " ${libdir}/rabbitmq/lib/${PN}-${PV}/* \
+                 ${localstatedir}/* \ 
+               "
+
+FILES_${PN}-doc += "LICENSE* INSTALL"
-- 
cgit v1.2.3-54-g00ecf