Update all automotive components

Latest revisions from 5.11 branch for all automotive components and
changing the recipe to for neptune3, which replaces both neptune-ui
and multiscreen-demo.

Neptune3 uses git-lfs, which needs to be enabled in the host system.

Task-number: QTAUTO-928
Change-Id: I8494f31267f5362655493155929264698a96d7b5
Reviewed-by: Dominik Holland <dominik.holland@pelagicore.com>

1 files changed, 93 insertions, 0 deletions

diff --git a/meta-boot2qt/recipes-qt/automotive/neptune3-ui_git.bb b/meta-boot2qt/recipes-qt/automotive/neptune3-ui_git.bb
new file mode 100644
index 0000000..f6be9cb
--- /dev/null
+++ b/meta-boot2qt/recipes-qt/automotive/neptune3-ui_git.bb
@@ -0,0 +1,93 @@
+############################################################################
+##
+## Copyright (C) 2018 The Qt Company Ltd.
+## Copyright (C) 2018 Pelagicore AG.
+## Contact: https://www.qt.io/licensing/
+##
+## This file is part of the Boot to Qt meta layer.
+##
+## $QT_BEGIN_LICENSE:GPL$
+## Commercial License Usage
+## Licensees holding valid commercial Qt licenses may use this file in
+## accordance with the commercial license agreement provided with the
+## Software or, alternatively, in accordance with the terms contained in
+## a written agreement between you and The Qt Company. For licensing terms
+## and conditions see https://www.qt.io/terms-conditions. For further
+## information use the contact form at https://www.qt.io/contact-us.
+##
+## GNU General Public License Usage
+## Alternatively, this file may be used under the terms of the GNU
+## General Public License version 3 or (at your option) any later version
+## approved by the KDE Free Qt Foundation. The licenses are as published by
+## the Free Software Foundation and appearing in the file LICENSE.GPL3
+## included in the packaging of this file. Please review the following
+## information to ensure the GNU General Public License requirements will
+## be met: https://www.gnu.org/licenses/gpl-3.0.html.
+##
+## $QT_END_LICENSE$
+##
+############################################################################
+
+DESCRIPTION = "Neptune 3 IVI UI"
+LICENSE = "Apache-2.0 & ( GPL-3.0 | The-Qt-Company-DCLA-2.1 )"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE.GPL3;md5=0d02f21f8e2533ecc519e2ed96bc94a2 \
+    file://imports/assets/fonts/LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57 \
+"
+
+inherit qt5-module systemd
+require recipes-qt/qt5/qt5-git.inc
+
+QT_GIT_PROJECT = "qt-apps"
+
+SRC_URI += " \
+    file://neptune.service \
+    "
+
+SRCREV = "716aadcbd88fbaa8f2b7bbf399cde1a4754e0def"
+
+DEPENDS = "\
+    qtbase \
+    qtdeclarative \
+    qttools-native \
+    qtquickcontrols2 \
+    qtapplicationmanager \
+    qtivi qtivi-native \
+    qtremoteobjects qtremoteobjects-native \
+    "
+RDEPENDS_${PN} = "\
+    dbus \
+    otf-noto ttf-opensans \
+    qtapplicationmanager qtapplicationmanager-tools \
+    qtvirtualkeyboard \
+    qtquickcontrols2-qmlplugins \
+    qtgraphicaleffects-qmlplugins \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'webengine', 'qtwebengine', '', d)} \
+    "
+
+do_install_append() {
+    install -m 0755 -d ${D}${systemd_unitdir}/system
+    install -m 0644 ${WORKDIR}/neptune.service ${D}${systemd_unitdir}/system/
+
+    # Move the fonts to the system-wide font location
+    install -m 0755 -d ${D}${datadir}/fonts/ttf/
+    mv ${D}/opt/neptune3/imports/assets/fonts/*.ttf ${D}${datadir}/fonts/ttf/
+    rm -rf ${D}/opt/neptune3/imports/assets/fonts/
+
+    # Don't package tests
+    rm -rf ${D}/usr/share/tests
+}
+
+PACKAGES =+ "${PN}-apps"
+RRECOMMENDS_${PN} += "${PN}-apps"
+
+FILES_${PN}-apps += "/opt/neptune3/apps"
+FILES_${PN} += "\
+    /opt/neptune3 \
+    ${datadir}/fonts/ttf \
+    "
+FILES_${PN}-dev += "\
+    /opt/neptune3/lib/*.so \
+    "
+
+SYSTEMD_SERVICE_${PN} = "neptune.service"