NUC: Use custom image layout

This patch adds a new image class 'image_dd', by default
it has an empty boot partition. image_dd_efi extends this
class to support Intel NUC board. The layout of a generated
image is a prerequisite for OSTree integarion.

Image generated by 'hddimg' produces rootfs.img (ext3
filesystem file) and then "live" boots it from initramfs
by mounting rootfs.img via loop device. For OTA integration
we need to access contents of rootfs.img already from
boot loader.

The custom 'image_nuc_efi' layout allow for fully atomic
updates on EFI based system, by keeping GRUB-EFI binary
on a dedicated EFI system partition (ESP). OSTree currently
is not fully atomic on EFI systems, but with this setup
we use GRUB-BIOS code path in OSTree, which is atomic.
After EFI firmware has loaded the GRUB-EFI binary, everything
else is done on rootfs parition.

One limitation from the above scenario is that you would
need to update /EFI/BOOT/bootx64.efi (GRUB-EFI) binary
manually. Not sure how common it is to update a boot loader
binary on a deployed system, but its not impossible.

Change-Id: Ibf2840aecd548000372131c4ded5cffa11ff1b0f
Reviewed-by: Teemu Holappa <teemu.holappa@theqtcompany.com>

1 files changed, 78 insertions, 0 deletions

diff --git a/classes/image_dd.bbclass b/classes/image_dd.bbclass
new file mode 100644
index 0000000..4d193b7
--- /dev/null
+++ b/classes/image_dd.bbclass
@@ -0,0 +1,78 @@
+##############################################################################
+##
+## Copyright (C) 2016 The Qt Company Ltd.
+## Contact: http://www.qt.io/licensing/
+##
+## This file is part of the Boot to Qt meta layer.
+##
+## $QT_BEGIN_LICENSE:COMM$
+##
+## Commercial License Usage
+## Licensees holding valid commercial Qt licenses may use this file in
+## accordance with the commercial license agreement provided with the
+## Software or, alternatively, in accordance with the terms contained in
+## a written agreement between you and The Qt Company. For licensing terms
+## and conditions see http://www.qt.io/terms-conditions. For further
+## information use the contact form at http://www.qt.io/contact-us.
+##
+## $QT_END_LICENSE$
+##
+##############################################################################
+
+# This class is based on meta-fsl-arm/classes/image_types_fsl.bbclass::generate_imx_sdcard()
+DESCRIPTION = "The base class for building images that can be deployed with GNU coreutils dd tool."
+inherit image_types
+
+IMAGE="${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.img"
+
+# Boot partition size [in KiB]
+BOOT_SPACE ?= "8192"
+
+# Set alignment to 4MB [in KiB]
+IMAGE_ROOTFS_ALIGNMENT = "4096"
+
+# Boot partition volume id
+BOOTDD_VOLUME_ID = "boot"
+
+IMAGE_TYPEDEP_dd = "ext3"
+IMAGE_DEPENDS_dd = "parted-native:do_populate_sysroot \
+                    dosfstools-native:do_populate_sysroot \
+                    mtools-native:do_populate_sysroot"
+
+image_dd_do_populate_boot() {
+}
+EXPORT_FUNCTIONS do_populate_boot
+
+IMAGE_CMD_dd() {
+
+    ROOTFS="${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
+
+    # Align boot partition and calculate total binary image size
+    BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
+    BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
+    IMAGE_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + $ROOTFS_SIZE + ${IMAGE_ROOTFS_ALIGNMENT})
+
+    # Initialize a sparse file
+    dd if=/dev/zero of=${IMAGE} bs=1 count=0 seek=$(expr 1024 \* ${IMAGE_SIZE})
+
+    # Create partition table
+    parted -s ${IMAGE} mklabel msdos
+    parted -s ${IMAGE} unit KiB mkpart primary fat32 ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED})
+    parted -s ${IMAGE} unit KiB mkpart primary $(expr  ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ $ROOTFS_SIZE)
+    parted -s ${IMAGE} set 1 boot on
+    parted ${IMAGE} print
+
+    # Create boot partition image
+    BOOT_BLOCKS=$(LC_ALL=C parted -s ${IMAGE} unit b print \
+                      | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 1024 }')
+    mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
+    do_populate_boot
+
+    # Burn Partitions
+    dd if=${WORKDIR}/boot.img of=${IMAGE} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
+    dd if=${ROOTFS} of=${IMAGE} conv=notrunc seek=1 bs=$(expr ${BOOT_SPACE_ALIGNED} \* 1024 + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
+
+    rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.img
+    ln -s ${IMAGE_NAME}.rootfs.img ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.img
+}
+